[gentoo-commits] repo/gentoo:master commit in: media-libs/libexif/

[Andreas Sturmlechner]

commit:     e25ec56d228a33edb9dd3284745245979a2e5411
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 18 09:15:13 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 18 09:22:45 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e25ec56d

media-libs/libexif: EAPI-7 bump

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 media-libs/libexif/libexif-0.6.21-r2.ebuild | 47 +++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/media-libs/libexif/libexif-0.6.21-r2.ebuild b/media-libs/libexif/libexif-0.6.21-r2.ebuild
new file mode 100644
index 00000000000..252bbbbc790
--- /dev/null
+++ b/media-libs/libexif/libexif-0.6.21-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="Library for parsing, editing, and saving EXIF data"
+HOMEPAGE="https://libexif.github.io/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc nls static-libs"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.6.13-pkgconfig.patch )
+
+src_prepare() {
+	default
+	sed -i -e '/FLAGS=/s:-g::' configure || die #390249
+	elibtoolize # For *-bsd
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf \
+		$(use_enable doc docs) \
+		$(use_enable nls) \
+		$(use_enable static-libs static) \
+		--with-doc-dir="${EPREFIX}"/usr/share/doc/${PF}
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	find "${D}" -name '*.la' -delete || die
+	rm -f "${ED}"/usr/share/doc/${PF}/{ABOUT-NLS,COPYING} || die
+}