[gentoo-commits] repo/gentoo:master commit in: x11-libs/libpciaccess/

[Mike Gilbert]

commit:     ecdb1e51c78f113f7419e43b95a5bd73d970d82f
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 01:40:40 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun Nov 28 19:54:07 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ecdb1e51

x11-libs/libpciaccess: migrate to hwdata

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 x11-libs/libpciaccess/libpciaccess-0.16-r1.ebuild | 31 +++++++++++++++++++++++
 1 file changed, 31 insertions(+)

diff --git a/x11-libs/libpciaccess/libpciaccess-0.16-r1.ebuild b/x11-libs/libpciaccess/libpciaccess-0.16-r1.ebuild
new file mode 100644
index 000000000000..1f46f6ac6927
--- /dev/null
+++ b/x11-libs/libpciaccess/libpciaccess-0.16-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+XORG_MULTILIB=yes
+XORG_EAUTORECONF=yes
+inherit xorg-3
+
+DESCRIPTION="Library providing generic access to the PCI bus and devices"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="zlib"
+
+DEPEND="
+	zlib? (	>=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}
+	sys-apps/hwdata"
+
+src_prepare() {
+	# Let autotools install scanpci (#765706)
+	sed 's@^noinst_@bin_@' -i scanpci/Makefile.am || die
+	xorg-3_src_prepare
+}
+
+src_configure() {
+	local XORG_CONFIGURE_OPTIONS=(
+		$(use_with zlib)
+		--with-pciids-path="${EPREFIX}"/usr/share/hwdata
+	)
+	xorg-3_src_configure
+}