[gentoo-commits] repo/gentoo:master commit in: app-crypt/gpgme/

[Sam James]

commit:     ab88be37c6c0c9c605acd4ae78a6338df8f02b9a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat May 28 18:18:24 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat May 28 18:18:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab88be37

app-crypt/gpgme: add LFS flags

Closes: https://bugs.gentoo.org/847955
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-crypt/gpgme/gpgme-1.17.1-r1.ebuild | 127 +++++++++++++++++++++++++++++++++
 1 file changed, 127 insertions(+)

diff --git a/app-crypt/gpgme/gpgme-1.17.1-r1.ebuild b/app-crypt/gpgme/gpgme-1.17.1-r1.ebuild
new file mode 100644
index 000000000000..18243537cea5
--- /dev/null
+++ b/app-crypt/gpgme/gpgme-1.17.1-r1.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_OPTIONAL=1
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/gnupg.asc
+
+inherit distutils-r1 libtool flag-o-matic qmake-utils toolchain-funcs verify-sig
+
+DESCRIPTION="GnuPG Made Easy is a library for making GnuPG easier to use"
+HOMEPAGE="http://www.gnupg.org/related_software/gpgme"
+SRC_URI="mirror://gnupg/gpgme/${P}.tar.bz2
+	verify-sig? ( mirror://gnupg/gpgme/${P}.tar.bz2.sig )"
+
+LICENSE="GPL-2 LGPL-2.1"
+# Please check ABI on each bump, even if SONAMEs didn't change: bug #833355
+# Use e.g. app-portage/iwdevtools integration with dev-libs/libabigail's abidiff.
+# Subslot: SONAME of each: <libgpgme.libgpgmepp.libqgpgme>
+SLOT="1/11.6.15"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="common-lisp static-libs +cxx python qt5 test"
+RESTRICT="!test? ( test )"
+
+# Note: On each bump, update dep bounds on each version from configure.ac!
+RDEPEND=">=app-crypt/gnupg-2
+	>=dev-libs/libassuan-2.5.3:=
+	>=dev-libs/libgpg-error-1.36:=
+	python? ( ${PYTHON_DEPS} )
+	qt5? ( dev-qt/qtcore:5 )"
+	#doc? ( app-doc/doxygen[dot] )
+DEPEND="${RDEPEND}
+	test? (
+		qt5? ( dev-qt/qttest:5 )
+	)"
+BDEPEND="python? ( dev-lang/swig )
+	verify-sig? ( sec-keys/openpgp-keys-gnupg )"
+
+REQUIRED_USE="qt5? ( cxx ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+do_python() {
+	if use python; then
+		pushd "lang/python" > /dev/null || die
+		top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_${EBUILD_PHASE}
+		popd > /dev/null || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	elibtoolize
+
+	# bug #697456
+	addpredict /run/user/$(id -u)/gnupg
+
+	local MAX_WORKDIR=66
+	if use test && [[ "${#WORKDIR}" -gt "${MAX_WORKDIR}" ]]; then
+		eerror "Unable to run tests as WORKDIR='${WORKDIR}' is longer than ${MAX_WORKDIR} which causes failure!"
+		die "Could not run tests as requested with too-long WORKDIR."
+	fi
+
+	# Make best effort to allow longer PORTAGE_TMPDIR
+	# as usock limitation fails build/tests
+	ln -s "${P}" "${WORKDIR}/b" || die
+	S="${WORKDIR}/b"
+}
+
+src_configure() {
+	local languages=()
+
+	use common-lisp && languages+=( "cl" )
+	use cxx && languages+=( "cpp" )
+	if use qt5; then
+		languages+=( "qt" )
+		#use doc ||
+		export DOXYGEN=true
+		export MOC="$(qt5_get_bindir)/moc"
+	fi
+
+	# bug #847955
+	append-lfs-flags
+
+	# bug #811933 for libassuan prefix
+	econf \
+		$(use test || echo "--disable-gpgconf-test --disable-gpg-test --disable-gpgsm-test --disable-g13-test") \
+		--enable-languages="${languages[*]}" \
+		--with-libassuan-prefix="${ESYSROOT}"/usr \
+		$(use_enable static-libs static)
+
+	use python && emake -C lang/python prepare
+
+	do_python
+}
+
+src_compile() {
+	default
+	do_python
+}
+
+src_test() {
+	default
+
+	if use python; then
+		test_python() {
+			emake -C lang/python/tests check \
+				PYTHON=${EPYTHON} \
+				PYTHONS=${EPYTHON} \
+				TESTFLAGS="--python-libdir=${BUILD_DIR}/lib"
+		}
+		python_foreach_impl test_python
+	fi
+}
+
+src_install() {
+	default
+
+	do_python
+
+	find "${ED}" -type f -name '*.la' -delete || die
+
+	# Backward compatibility for gentoo
+	# (in the past, we had slots)
+	dodir /usr/include/gpgme
+	dosym ../gpgme.h /usr/include/gpgme/gpgme.h
+}