[gentoo-commits] proj/kde:master commit in: kde-apps/ark/

[Andreas Sturmlechner]

commit:     0cef5ec61971f3a5d8f6bf060db14f8edb6e57d9
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 29 16:24:33 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov 29 16:43:05 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=0cef5ec6

kde-apps/ark: drop 21.11.90*

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/ark/ark-21.11.90.ebuild | 80 ----------------------------------------
 1 file changed, 80 deletions(-)

diff --git a/kde-apps/ark/ark-21.11.90.ebuild b/kde-apps/ark/ark-21.11.90.ebuild
deleted file mode 100644
index 49b1f4b183..0000000000
--- a/kde-apps/ark/ark-21.11.90.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="optional"
-KFMIN=5.88.0
-QTMIN=5.15.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org optfeature
-
-DESCRIPTION="File archiver by KDE"
-HOMEPAGE="https://apps.kde.org/ark/ https://utils.kde.org/projects/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="zip"
-
-RDEPEND="
-	app-arch/libarchive:=[bzip2,lzma,zlib]
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.2.0:= )
-"
-DEPEND="${RDEPEND}
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	test? ( >=dev-libs/libzip-1.2.0:= )
-"
-BDEPEND="
-	sys-devel/gettext
-	test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# bug 822177: may segfault or hang indefinitely
-		-E "(kerfuffle-addtoarchivetest)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "rar archive creation/extraction" app-arch/rar
-		optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
-		optfeature "7-Zip archive support" app-arch/p7zip
-		optfeature "lrz archive support" app-arch/lrzip
-		optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
-	fi
-	ecm_pkg_postinst
-}