[gentoo-commits] gentoo-x86 commit in media-libs/libmediainfo: ChangeLog libmediainfo-0.7.57.ebuild

[Tim Harder (radhermit)]

radhermit    12/05/03 13:03:47

  Modified:             ChangeLog
  Added:                libmediainfo-0.7.57.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.42                 media-libs/libmediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	12 Apr 2012 23:45:48 -0000	1.41
+++ ChangeLog	3 May 2012 13:03:47 -0000	1.42
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.41 2012/04/12 23:45:48 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.42 2012/05/03 13:03:47 radhermit Exp $
+
+*libmediainfo-0.7.57 (03 May 2012)
+
+  03 May 2012; Tim Harder <radhermit@g.o> +libmediainfo-0.7.57.ebuild,
+  +files/libmediainfo-0.7.57-system-tinyxml.patch:
+  Version bump.
 
 *libmediainfo-0.7.56 (12 Apr 2012)
 



1.1                  media-libs/libmediainfo/libmediainfo-0.7.57.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.57.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.57.ebuild?rev=1.1&content-type=text/plain

Index: libmediainfo-0.7.57.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.57.ebuild,v 1.1 2012/05/03 13:03:47 radhermit Exp $

EAPI="4"

inherit autotools multilib flag-o-matic eutils

MY_PN="MediaInfo"
DESCRIPTION="MediaInfo libraries"
HOMEPAGE="http://mediainfo.sourceforge.net/"
SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl doc mms static-libs"

RDEPEND="sys-libs/zlib
	>=dev-libs/tinyxml-2.6.2[stl]
	>=media-libs/libzen-0.4.26[static-libs=]
	curl? ( net-misc/curl )
	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"

src_prepare() {
	pushd "${WORKDIR}"/${MY_PN}Lib > /dev/null
	epatch "${FILESDIR}"/${P}-system-tinyxml.patch
	popd > /dev/null

	# Don't force -O2 by default
	sed -i -e "s:-O2::" configure.ac

	append-flags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
	append-flags -DTIXML_USE_STL
	eautoreconf
}

src_configure() {
	econf \
		--enable-shared \
		--with-libtinyxml \
		$(use_with curl libcurl) \
		$(use_with mms libmms) \
		$(use_enable static-libs static) \
		$(use_enable static-libs staticlibs)
}

src_compile() {
	default

	if use doc; then
		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
		doxygen Doxyfile || die
	fi
}

src_install() {
	default

	insinto /usr/$(get_libdir)/pkgconfig
	doins "${S}"/${PN}.pc

	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto /usr/include/${MY_PN}/${x}
		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
	done

	insinto /usr/include/${MY_PN}DLL
	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h

	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
	if use doc; then
		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +
}