[gentoo-commits] gentoo-x86 commit in sci-physics/espresso: ChangeLog espresso-3.0.2.ebuild espresso-3.0.1.ebuild

[Christoph Junghans (ottxor)]

ottxor      11/11/27 21:09:29

  Modified:             ChangeLog
  Added:                espresso-3.0.2.ebuild
  Removed:              espresso-3.0.1.ebuild
  Log:
  Version bump + qa fixes (bug #392123)
  
  (Portage version: 2.2.0_alpha78/cvs/Linux i686)

Revision  Changes    Path
1.4                  sci-physics/espresso/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	27 May 2011 17:34:23 -0000	1.3
+++ ChangeLog	27 Nov 2011 21:09:29 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for sci-physics/espresso
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v 1.3 2011/05/27 17:34:23 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/ChangeLog,v 1.4 2011/11/27 21:09:29 ottxor Exp $
+
+*espresso-3.0.2 (27 Nov 2011)
+
+  27 Nov 2011; Christoph Junghans <ottxor@g.o> -espresso-3.0.1.ebuild,
+  +espresso-3.0.2.ebuild:
+  Version bump + qa fixes (bug #392123)
 
 *espresso-3.0.1 (27 May 2011)
 



1.1                  sci-physics/espresso/espresso-3.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/espresso-3.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/espresso/espresso-3.0.2.ebuild?rev=1.1&content-type=text/plain

Index: espresso-3.0.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/espresso/espresso-3.0.2.ebuild,v 1.1 2011/11/27 21:09:29 ottxor Exp $

EAPI=4

inherit autotools-utils savedconfig

DESCRIPTION="Extensible Simulation Package for Research on Soft matter"
HOMEPAGE="http://www.espressomd.org"

if [ "${PV%9999}" != "${PV}" ]; then
	EGIT_REPO_URI="git://git.savannah.nongnu.org/espressomd.git"
	EGIT_BRANCH="master"
	inherit git-2
else
	SRC_URI="mirror://nongnu/${PN}md/${P}.tar.gz"
fi

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86"
IUSE="X doc examples fftw mpi packages test -tk"
REQUIRED_USE="tk? ( X )"

RESTRICT="tk? ( test )"

RDEPEND="
	dev-lang/tcl
	fftw? ( sci-libs/fftw:3.0 )
	mpi? ( virtual/mpi )
	tk? ( >=dev-lang/tk-8.4.18-r1 )
	X? ( x11-libs/libX11 )"

DEPEND="${RDEPEND}
	doc? (
		app-doc/doxygen[-nodot]
		virtual/latex-base )"

DOCS=( AUTHORS NEWS README ChangeLog )

src_prepare() {
	autotools-utils_src_prepare
	eautoreconf
	restore_config myconfig.h
}

src_configure() {
	myeconfargs=(
		$(use_with fftw) \
		$(use_with mpi) \
		$(use_with tk) \
		$(use_with X x)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile doc
}

src_install() {
	autotools-utils_src_install

	insinto /usr/share/${PN}
	doins ${AUTOTOOLS_BUILD_DIR}/myconfig-sample.h

	save_config ${AUTOTOOLS_BUILD_DIR}/src/myconfig-final.h

	if use doc; then
		local where="."
		[ "${PV%9999}" != "${PV}" ] && where="${AUTOTOOLS_BUILD_DIR}"
		newdoc ${where}/doc/ug/ug.pdf user_guide.pdf
		dohtml -r ${AUTOTOOLS_BUILD_DIR}/doc/dg/html/*
		newdoc ${where}/doc/tutorials/tut2/tut2.pdf tutorial.pdf
	fi

	if use examples; then
		insinto /usr/share/${PN}/examples
		doins -r samples/*
	fi

	if use packages; then
		insinto /usr/share/${PN}/packages
		doins -r packages/*
	fi
}

pkg_postinst() {
	elog
	elog "Please read and cite:"
	elog "ESPResSo, Comput. Phys. Commun. 174(9) ,704, 2006."
	elog "http://dx.doi.org/10.1016/j.cpc.2005.10.005"
	elog
	elog "If you need more features, change"
	elog "/etc/portage/savedconfig/${CATEGORY}/${PF}"
	elog "and reemerge with USE=savedconfig"
	elog
	elog "For a full feature list see:"
	elog "/usr/share/${PN}/myconfig-sample.h"
	elog
}