[gentoo-commits] gentoo-x86 commit in net-im/psimedia: psimedia-1.0.3-r2.ebuild ChangeLog

[Peter Volkov (pva)]

pva         11/04/01 14:24:13

  Modified:             ChangeLog
  Added:                psimedia-1.0.3-r2.ebuild
  Log:
  Fixed CFLAGS pollution (-g), bug #361449 thank Agostino Sarubbo (amd64 AT) for report.
  
  (Portage version: 2.1.9.45/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 net-im/psimedia/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psimedia/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psimedia/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psimedia/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/psimedia/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	31 Mar 2011 07:46:45 -0000	1.16
+++ ChangeLog	1 Apr 2011 14:24:13 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/psimedia
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/psimedia/ChangeLog,v 1.16 2011/03/31 07:46:45 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/psimedia/ChangeLog,v 1.17 2011/04/01 14:24:13 pva Exp $
+
+*psimedia-1.0.3-r2 (01 Apr 2011)
+
+  01 Apr 2011; Peter Volkov <pva@g.o> +psimedia-1.0.3-r2.ebuild:
+  Fixed CFLAGS pollution (-g), bug #361449 thank Agostino Sarubbo (amd64 AT)
+  for report.
 
   31 Mar 2011; Samuli Suominen <ssuominen@g.o> psimedia-1.0.3-r1.ebuild,
   +files/psimedia-1.0.3-linux-headers-2.6.38.patch:



1.1                  net-im/psimedia/psimedia-1.0.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psimedia/psimedia-1.0.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psimedia/psimedia-1.0.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: psimedia-1.0.3-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/psimedia/psimedia-1.0.3-r2.ebuild,v 1.1 2011/04/01 14:24:13 pva Exp $

EAPI="2"

inherit eutils qt4-r2 multilib

DESCRIPTION="Psi plugin for voice/video calls"
HOMEPAGE="http://delta.affinix.com/psimedia/"
SRC_URI="http://delta.affinix.com/download/psimedia/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
IUSE="demo"

COMMON_DEPEND=">=dev-libs/glib-2.18
	>=media-libs/gstreamer-0.10.22
	>=media-libs/gst-plugins-base-0.10.22
	media-libs/gst-plugins-good
	>=dev-libs/liboil-0.3
	>=x11-libs/qt-gui-4.4:4
	>=media-libs/speex-1.2_rc1
"
RDEPEND="${COMMON_DEPEND}
	media-plugins/gst-plugins-speex
	>=media-plugins/gst-plugins-vorbis-0.10.22
	>=media-plugins/gst-plugins-theora-0.10.22
	>=media-plugins/gst-plugins-alsa-0.10.22
	>=media-plugins/gst-plugins-ogg-0.10.22
	media-plugins/gst-plugins-v4l2
	media-plugins/gst-plugins-jpeg
	!<net-im/psi-0.13_rc1
"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
"

src_prepare() {
	sed -e '/^TEMPLATE/a CONFIG += ordered' -i psimedia.pro || die
	# Don't build demo if we don't need that.
	use demo || { sed -e '/^SUBDIRS[[:space:]]*+=[[:space:]]*demo[[:space:]]*$/d;' -i psimedia.pro || die; }
	# Remove support for V4L v1 because linux-headers-2.6.38 stopped shipping linux/videodev.h.
	epatch "${FILESDIR}"/${P}-linux-headers-2.6.38.patch
}

src_configure() {
	# qconf generaged configure script...
	./configure --no-separate-debug-info || die

	eqmake4
}

src_install() {
	insinto /usr/$(get_libdir)/psi/plugins
	doins gstprovider/libgstprovider.so || die

	if use demo; then
		exeinto /usr/$(get_libdir)/${PN}
		newexe demo/demo ${PN} || die

		# Create /usr/bin/psimedia
		cat <<-EOF > "demo/${PN}"
		#!/bin/bash

		export PSI_MEDIA_PLUGIN=/usr/$(get_libdir)/psi/plugins/libgstprovider.so
		/usr/$(get_libdir)/${PN}/${PN}
		EOF

		dobin demo/${PN} || die
	fi
}