[gentoo-commits] gentoo-x86 commit in media-sound/clementine: clementine-0.1.ebuild ChangeLog metadata.xml

[Samuli Suominen (ssuominen)]

ssuominen    10/02/22 19:57:22

  Added:                clementine-0.1.ebuild ChangeLog metadata.xml
  Log:
  Initial commit.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-sound/clementine/clementine-0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/clementine-0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/clementine-0.1.ebuild?rev=1.1&content-type=text/plain

Index: clementine-0.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/clementine/clementine-0.1.ebuild,v 1.1 2010/02/22 19:57:21 ssuominen Exp $

EAPI=2
inherit eutils gnome2-utils qt4-r2

DESCRIPTION="A modern music player and library organizer based on Amarok 1.4 and Qt4"
HOMEPAGE="http://code.google.com/p/clementine-player/"
SRC_URI="http://clementine-player.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="x11-libs/qt-gui:4
	x11-libs/qt-sql:4[sqlite]
	x11-libs/qt-opengl:4
	media-libs/liblastfm
	x11-libs/libnotify
	media-libs/xine-lib
	media-libs/taglib
	dev-libs/glib:2"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	sed -i \
		-e "s:application-x-${PN}:${PN}:" \
		dist/${PN}.desktop || die

	qt4-r2_src_prepare
}

src_install() {
	dobin src/${PN} || die

	local res
	for res in 16 32 64; do
		insinto /usr/share/icons/hicolor/${res}x${res}/apps
		newins dist/${PN}_${res}.png ${PN}.png || die
	done

	domenu dist/${PN}.desktop

	dodoc TODO
}

pkg_preinst() { gnome2_icon_savelist; }
pkg_postinst() { gnome2_icon_cache_update; }
pkg_postrm() { gnome2_icon_cache_update; }



1.1                  media-sound/clementine/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/clementine
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/clementine/ChangeLog,v 1.1 2010/02/22 19:57:21 ssuominen Exp $

*clementine-0.1 (22 Feb 2010)

  22 Feb 2010; Samuli Suominen <ssuominen@g.o>
  +clementine-0.1.ebuild:
  Initial commit.




1.1                  media-sound/clementine/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/clementine/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sound</herd>
</pkgmetadata>