[gentoo-commits] gentoo-x86 commit in x11-apps/xinit: ChangeLog xinit-1.3.2.ebuild

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    12/01/31 21:28:16

  Modified:             ChangeLog
  Added:                xinit-1.3.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.224                x11-apps/xinit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-apps/xinit/ChangeLog?rev=1.224&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-apps/xinit/ChangeLog?rev=1.224&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-apps/xinit/ChangeLog?r1=1.223&r2=1.224

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-apps/xinit/ChangeLog,v
retrieving revision 1.223
retrieving revision 1.224
diff -u -r1.223 -r1.224
--- ChangeLog	27 Dec 2011 20:55:01 -0000	1.223
+++ ChangeLog	31 Jan 2012 21:28:16 -0000	1.224
@@ -1,6 +1,12 @@
 # ChangeLog for x11-apps/xinit
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-apps/xinit/ChangeLog,v 1.223 2011/12/27 20:55:01 maekke Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-apps/xinit/ChangeLog,v 1.224 2012/01/31 21:28:16 chithanh Exp $
+
+*xinit-1.3.2 (31 Jan 2012)
+
+  31 Jan 2012; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +xinit-1.3.2.ebuild:
+  Version bump.
 
   27 Dec 2011; Markus Meier <maekke@g.o> xinit-1.3.1-r1.ebuild:
   x86 stable, bug #394393



1.1                  x11-apps/xinit/xinit-1.3.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-apps/xinit/xinit-1.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-apps/xinit/xinit-1.3.2.ebuild?rev=1.1&content-type=text/plain

Index: xinit-1.3.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-apps/xinit/xinit-1.3.2.ebuild,v 1.1 2012/01/31 21:28:16 chithanh Exp $

EAPI=4

inherit xorg-2

DESCRIPTION="X Window System initializer"

LICENSE="${LICENSE} GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="+minimal"

RDEPEND="
	!<x11-base/xorg-server-1.8.0
	x11-apps/xauth
	x11-libs/libX11
"
DEPEND="${RDEPEND}"
PDEPEND="x11-apps/xrdb
	!minimal? (
		x11-apps/xclock
		x11-apps/xsm
		x11-terms/xterm
		x11-wm/twm
	)
"

PATCHES=(
	"${FILESDIR}/0001-Gentoo-customizations.patch"
)

pkg_setup() {
	xorg-2_pkg_setup

	XORG_CONFIGURE_OPTIONS=(
		--with-xinitdir=/etc/X11/xinit
	)
}

src_install() {
	xorg-2_src_install

	exeinto /etc/X11
	doexe "${FILESDIR}"/chooser.sh "${FILESDIR}"/startDM.sh
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}"/Xsession
	exeinto /etc/X11/xinit
	doexe "${FILESDIR}"/xserverrc
	exeinto /etc/X11/xinit/xinitrc.d/
	doexe "${FILESDIR}/00-xhost"

	insinto /usr/share/xsessions
	doins "${FILESDIR}/Xsession.desktop"
}

pkg_postinst() {
	xorg-2_pkg_postinst
	ewarn "If you use startx to start X instead of a login manager like gdm/kdm,"
	ewarn "you can set the XSESSION variable to anything in /etc/X11/Sessions/ or"
	ewarn "any executable. When you run startx, it will run this as the login session."
	ewarn "You can set this in a file in /etc/env.d/ for the entire system,"
	ewarn "or set it per-user in ~/.bash_profile (or similar for other shells)."
	ewarn "Here's an example of setting it for the whole system:"
	ewarn "    echo XSESSION=\"Gnome\" > /etc/env.d/90xsession"
	ewarn "    env-update && source /etc/profile"
}