[gentoo-commits] repo/gentoo:master commit in: net-libs/libnxml/

[Sam James]

commit:     61b447bb8c543b3f7ce5b288193a7c33b418bc08
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 31 03:38:07 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Aug 31 03:44:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61b447bb

net-libs/libnxml: fix installed pkgconfig file

The installed pkgconfig file referred to /usr/lib unconditionally,
causing warnings in reverse dependencies when linking.

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-libs/libnxml/libnxml-0.18.3-r1.ebuild | 54 +++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/net-libs/libnxml/libnxml-0.18.3-r1.ebuild b/net-libs/libnxml/libnxml-0.18.3-r1.ebuild
new file mode 100644
index 00000000000..f973f45b72e
--- /dev/null
+++ b/net-libs/libnxml/libnxml-0.18.3-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A C-library for parsing and writing XML 1.0/1.1 files or streams"
+HOMEPAGE="https://www.autistici.org/bakunin/libnxml/doc/"
+SRC_URI="https://www.autistici.org/bakunin/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~sparc ~x86"
+IUSE="doc examples"
+
+RDEPEND="net-misc/curl"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	# Fix lib dir in installed pkgconfig file
+	sed -i -e "s:\${exec_prefix}/lib:\${exec_prefix}/$(get_libdir):" nxml.pc.in \
+		|| die "Failed to correct pkgconfig file"
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		ebegin "Creating documentation"
+		doxygen doxy.conf || die "generating docs failed"
+		# clean out doxygen gunk
+		rm doc/html/*.{md5,map} || die
+		HTML_DOCS=( doc/html/. )
+		eend 0
+	fi
+}
+
+src_install() {
+	default
+
+	if use examples; then
+		docinto test
+		dodoc test/*.c
+	fi
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}