[gentoo-commits] gentoo-x86 commit in media-gfx/nip2: ChangeLog nip2-7.22.2.ebuild

[Peter Volkov (pva)]

pva         10/09/03 15:39:28

  Modified:             ChangeLog
  Added:                nip2-7.22.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.26                 media-gfx/nip2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	25 Jun 2010 11:06:16 -0000	1.25
+++ ChangeLog	3 Sep 2010 15:39:28 -0000	1.26
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/nip2
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.25 2010/06/25 11:06:16 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.26 2010/09/03 15:39:28 pva Exp $
+
+*nip2-7.22.2 (03 Sep 2010)
+
+  03 Sep 2010; Peter Volkov <pva@g.o> +nip2-7.22.2.ebuild:
+  Version bump.
 
   25 Jun 2010; Peter Volkov <pva@g.o> +nip2-7.22.1.ebuild,
   metadata.xml:



1.1                  media-gfx/nip2/nip2-7.22.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/nip2-7.22.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/nip2-7.22.2.ebuild?rev=1.1&content-type=text/plain

Index: nip2-7.22.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/nip2-7.22.2.ebuild,v 1.1 2010/09/03 15:39:28 pva Exp $

EAPI=2
inherit eutils autotools fdo-mime gnome2-utils versionator

MY_MAJ_VER=$(get_version_component_range 1-2)
DESCRIPTION="VIPS Image Processing Graphical User Interface"
SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/${MY_MAJ_VER}/${P}.tar.gz"
HOMEPAGE="http://vips.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="fftw goffice gsl test"

RDEPEND=">=dev-libs/glib-2.14:2
	dev-libs/libxml2
	x11-misc/xdg-utils
	>=media-libs/vips-${MY_MAJ_VER}
	>=x11-libs/gtk+-2.18:2
	goffice? ( x11-libs/goffice:0.8 )
	gsl? ( sci-libs/gsl )
	fftw? ( sci-libs/fftw:3.0 )"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex
	test? ( media-libs/vips[jpeg,lcms] )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.16.4-fftw3-build.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-update-desktop \
		$(use_with goffice libgoffice) \
		$(use_with gsl) \
		$(use_with fftw fftw3)
}

src_test() {
	if ! use gsl; then
		ewarn "Some tests require USE=gsl. Disabling test_math.ws tests."
		rm test/workspaces/test_math.ws
	fi
	make check || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README* || die
	insinto /usr/share/icons/hicolor/128x128/apps
	newins share/nip2/data/vips-128.png nip2.png || die
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}