[gentoo-commits] repo/gentoo:master commit in: net-vpn/networkmanager-libreswan/

[Matt Turner]

commit:     74625b522de566ec1dd1ee3746ca15ab5f9be2b2
Author:     Matthew Smith <matt <AT> offtopica <DOT> uk>
AuthorDate: Thu Dec 30 09:51:00 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr  8 21:20:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=74625b52

net-vpn/networkmanager-libreswan: Change metainfo dir

Closes: https://github.com/gentoo/gentoo/pull/23579
Signed-off-by: Matthew Smith <matt <AT> offtopica.uk>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 .../networkmanager-libreswan-1.2.14-r1.ebuild      | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/net-vpn/networkmanager-libreswan/networkmanager-libreswan-1.2.14-r1.ebuild b/net-vpn/networkmanager-libreswan/networkmanager-libreswan-1.2.14-r1.ebuild
new file mode 100644
index 000000000000..56dc1cf4e91b
--- /dev/null
+++ b/net-vpn/networkmanager-libreswan/networkmanager-libreswan-1.2.14-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager libreswan plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager/VPN"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libnl-3.2.8:3
+	>=net-misc/networkmanager-1.2.0:=
+	net-vpn/libreswan
+	gtk? (
+		app-crypt/libsecret
+		>=gnome-extra/nm-applet-1.2.0
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	sed -i 's|/appdata|/metainfo|g' Makefile.{in,am} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		--disable-more-warnings
+		--disable-static
+		--with-dist-version=Gentoo
+		--without-libnm-glib
+		$(use_with gtk gnome)
+	)
+	gnome2_src_configure "${myconf[@]}"
+}