[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgusb/

[Matt Turner]

commit:     45513620ce8e32bc130f9867a874a36d4ecae9b4
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue May 25 18:35:39 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue May 25 18:51:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45513620

dev-libs/libgusb: Version bump to 0.3.7

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgusb/Manifest             |  1 +
 dev-libs/libgusb/libgusb-0.3.7.ebuild | 74 +++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-libs/libgusb/Manifest b/dev-libs/libgusb/Manifest
index 45f40d3cea7..68c3b7f7fd9 100644
--- a/dev-libs/libgusb/Manifest
+++ b/dev-libs/libgusb/Manifest
@@ -1 +1,2 @@
 DIST libgusb-0.3.6.tar.xz 41648 BLAKE2B c4fe7661c3912233022c90b6201e2e9007871355dd2c7f6a67a96da77ab1d3c937bad9cc44fc8a91f89e93a66c6a072e0835e0e9178e9352b0bab73463bece3c SHA512 a185b6feaeace72f78672ebaa6788659fcccb5d6414d49afb8ab717307c7a3d8e55a2adaaadc24f00ee0059fc1e3fcee54212ac3477989f7cbe4aebbf91699c2
+DIST libgusb-0.3.7.tar.xz 41844 BLAKE2B e0829430a7c4c9372ebc061ca8245ecd6b30f0922e4e37ae41f7f65055e7339b5a3a882c5526ea5e5663be3b7c1ad71fee7da5cffb501d63bd1cda2b618fd40d SHA512 65a35be62bff689621f418abf045f62f946c67488dd021d363ab252b9b3a2380898ec763b374f7da50901945eda666fdcae7cbfda7e143544175d7ade3ebc20d

diff --git a/dev-libs/libgusb/libgusb-0.3.7.ebuild b/dev-libs/libgusb/libgusb-0.3.7.ebuild
new file mode 100644
index 00000000000..4ff3c4ea094
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.3.7.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson multilib-minimal python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk-doc +introspection static-libs test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	sys-apps/hwids
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.4
+		dev-util/gtk-doc
+	)
+	vala? ( $(vala_depend) )
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	default
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+		$(meson_use test tests)
+		-Dvapi=$(multilib_native_usex vala true false)
+		-Dusb_ids="${EPREFIX}"/usr/share/misc/usb.ids
+		-Ddocs=$(multilib_native_usex gtk-doc true false)
+		-Dintrospection=$(multilib_native_usex introspection true false)
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}