[gentoo-commits] gentoo-x86 commit in sys-fs/multipath-tools: ChangeLog multipath-tools-0.4.9.ebuild

[Tim Harder (radhermit)]

radhermit    10/10/28 06:28:41

  Modified:             ChangeLog
  Added:                multipath-tools-0.4.9.ebuild
  Log:
  Version bump (bug #321331 by Krzysiek). Update build patch and remove patches applied upstream, remove -j1 limitation, and use emake instead of make.
  
  (Portage version: 2.2_rc98/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 sys-fs/multipath-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/multipath-tools/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	13 Nov 2009 01:01:06 -0000	1.33
+++ ChangeLog	28 Oct 2010 06:28:41 -0000	1.34
@@ -1,6 +1,14 @@
 # ChangeLog for sys-fs/multipath-tools
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.33 2009/11/13 01:01:06 josejx Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.34 2010/10/28 06:28:41 radhermit Exp $
+
+*multipath-tools-0.4.9 (28 Oct 2010)
+
+  28 Oct 2010; Tim Harder <radhermit@g.o>
+  +multipath-tools-0.4.9.ebuild, +files/multipath-tools-0.4.9-build.patch:
+  Version bump (bug #321331 by Krzysiek). Update build patch and remove
+  patches applied upstream, remove -j1 limitation, and use emake instead of
+  make.
 
   13 Nov 2009; Joseph Jezak <josejx@g.o>
   multipath-tools-0.4.8-r1.ebuild:



1.1                  sys-fs/multipath-tools/multipath-tools-0.4.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.9.ebuild?rev=1.1&content-type=text/plain

Index: multipath-tools-0.4.9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.9.ebuild,v 1.1 2010/10/28 06:28:41 radhermit Exp $

EAPI=2
inherit eutils toolchain-funcs

DESCRIPTION="Device mapper target autoconfig"
HOMEPAGE="http://christophe.varoqui.free.fr/"
SRC_URI="http://christophe.varoqui.free.fr/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE=""

RDEPEND="|| (
		>=sys-fs/lvm2-2.02.45
		>=sys-fs/device-mapper-1.00.19-r1
	)
	>=sys-fs/udev-124
	sys-fs/sysfsutils
	dev-libs/libaio"
DEPEND="${RDEPEND}"

S="${WORKDIR}"

src_prepare() {
	 epatch "${FILESDIR}"/${P}-build.patch
	 # kpartx fails on extended partitions
	 epatch "${FILESDIR}"/${PN}-0.4.8-kparted-ext-partitions.patch
}

src_compile() {
	emake CC="$(tc-getCC)" || die "emake failed"
}

src_install() {
	dodir /sbin /usr/share/man/man8
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto /etc
	newins "${S}"/multipath.conf.annotated multipath.conf
	fperms 644 /etc/udev/rules.d/65-multipath.rules
	fperms 644 /etc/udev/rules.d/66-kpartx.rules
	# This is the monitoring daemon
	newinitd "${FILESDIR}"/rc-multipathd multipathd
	# This is the init script that fires the multipath addon for baselayout2
	newinitd "${FILESDIR}"/init.d-multipath-0.4.8-r1 multipath
	# Handle early-boot startup as well as shutdown of multipath devices
	insinto /lib/rcscripts/addons
	doins "${FILESDIR}"/multipath-start.sh
	doins "${FILESDIR}"/multipath-stop.sh

	dodoc multipath.conf.*
	dodoc AUTHOR ChangeLog FAQ README TODO
	docinto kpartx; dodoc kpartx/ChangeLog kpartx/README
}

pkg_preinst() {
	# The dev.d script was previously wrong and is now removed (the udev rules
	# file does the job instead), but it won't be removed from live systems due
	# to cfgprotect.
	# This should help out a little...
	if [[ -e ${ROOT}/etc/dev.d/block/multipath.dev ]] ; then
		mkdir -p "${D}"/etc/dev.d/block
		echo "# Please delete this file. It is obsoleted by /etc/udev/rules.d/65-multipath.rules" \
			> "${D}"/etc/dev.d/block/multipath.dev
	fi
}

pkg_postinst() {
	elog "If you need multipath on your system, you should ensure that a"
	elog "'multipath' entry is present in your RC_VOLUME_ORDER variable!"
	elog "If you use baselayout2, you must add 'multipath' into"
	elog "your boot runlevel!"
}