[gentoo-commits] gentoo-x86 commit in net-libs/liboauth: liboauth-0.9.0.ebuild ChangeLog liboauth-0.8.9.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/09/10 12:31:22

  Modified:             ChangeLog
  Added:                liboauth-0.9.0.ebuild
  Removed:              liboauth-0.8.9.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2_rc78/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-libs/liboauth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/liboauth/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/liboauth/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/liboauth/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/liboauth/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	31 Aug 2010 00:04:18 -0000	1.3
+++ ChangeLog	10 Sep 2010 12:31:22 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/liboauth
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/liboauth/ChangeLog,v 1.3 2010/08/31 00:04:18 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/liboauth/ChangeLog,v 1.4 2010/09/10 12:31:22 flameeyes Exp $
+
+*liboauth-0.9.0 (10 Sep 2010)
+
+  10 Sep 2010; Diego E. Pettenò <flameeyes@g.o>
+  -liboauth-0.8.9.ebuild, +liboauth-0.9.0.ebuild:
+  Version bump.
 
   31 Aug 2010; Diego E. Pettenò <flameeyes@g.o>
   liboauth-0.8.9.ebuild:



1.1                  net-libs/liboauth/liboauth-0.9.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/liboauth/liboauth-0.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/liboauth/liboauth-0.9.0.ebuild?rev=1.1&content-type=text/plain

Index: liboauth-0.9.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/liboauth/liboauth-0.9.0.ebuild,v 1.1 2010/09/10 12:31:22 flameeyes Exp $

EAPI=2

DESCRIPTION="C library implementing the OAuth secure authentication protocol"
HOMEPAGE="http://liboauth.sourceforge.net/"
SRC_URI="http://liboauth.sourceforge.net/pool/${P}.tar.gz"

LICENSE="|| ( GPL-2 MIT )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl doc bindist +nss"

CDEPEND="
	nss? ( dev-libs/nss
		curl? ( || ( net-misc/curl[ssl,nss,-gnutls] net-misc/curl[-ssl] ) )
	)

	bindist? ( dev-libs/nss
		curl? ( || ( net-misc/curl[ssl,nss,-gnutls] net-misc/curl[-ssl] ) )
	)

	!bindist? (
		!nss? ( dev-libs/openssl
			curl? ( || ( net-misc/curl[ssl,-nss,-gnutls] net-misc/curl[-ssl] ) )
		)
	)

	net-misc/curl
"

RDEPEND="${CDEPEND}"

DEPEND="${CDEPEND}
	doc? (
		app-doc/doxygen
		media-gfx/graphviz
		media-fonts/freefont-ttf
	)
	dev-util/pkgconfig"

src_configure() {
	local myconf=

	if use nss || use bindist; then
		myconf="${myconf} --enable-nss"
	else
		myconf="${myconf} --disable-nss"
	fi

	econf \
		--disable-dependency-tracking \
		--enable-fast-install \
		--disable-static \
		$(use_enable !curl curl) \
		$(use_enable curl libcurl) \
		${myconf}
}

src_compile() {
	emake || die "emake failed"

	if use doc ; then
		# make sure fonts are found
		export DOTFONTPATH=/usr/share/fonts/freefont-ttf
		emake dox || die "emake dox failed"
	fi
}

src_test() {
	# explicitly allow parallel test build
	emake check || die "emake check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"

	find "${D}" -name '*.la' -delete || die

	dodoc AUTHORS ChangeLog LICENSE.OpenSSL NEWS README || die "dodoc failed"

	if use doc; then
		dohtml -r doc/html/* || die "dohtml failed"
	fi
}