[gentoo-commits] gentoo-x86 commit in xfce-base/xfce4-session: ChangeLog xfce4-session-4.10.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/04/29 10:24:28

  Modified:             ChangeLog
  Added:                xfce4-session-4.10.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.159                xfce-base/xfce4-session/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?rev=1.159&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?rev=1.159&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?r1=1.158&r2=1.159

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v
retrieving revision 1.158
retrieving revision 1.159
diff -u -r1.158 -r1.159
--- ChangeLog	20 Apr 2012 20:19:04 -0000	1.158
+++ ChangeLog	29 Apr 2012 10:24:28 -0000	1.159
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.158 2012/04/20 20:19:04 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.159 2012/04/29 10:24:28 ssuominen Exp $
+
+*xfce4-session-4.10.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@g.o>
+  +xfce4-session-4.10.0.ebuild:
+  Version bump.
 
   20 Apr 2012; Samuli Suominen <ssuominen@g.o>
   -xfce4-session-4.8.3.ebuild, -xfce4-session-4.9.0-r1.ebuild,



1.1                  xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild?rev=1.1&content-type=text/plain

Index: xfce4-session-4.10.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild,v 1.1 2012/04/29 10:24:28 ssuominen Exp $

EAPI=4
inherit xfconf

DESCRIPTION="A session manager for the Xfce desktop environment"
HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="consolekit debug gnome-keyring policykit udev +xscreensaver"

COMMON_DEPEND=">=dev-libs/dbus-glib-0.98
	x11-apps/iceauth
	x11-libs/libSM
	>=x11-libs/libwnck-2.30:1
	x11-libs/libX11
	>=xfce-base/libxfce4util-4.10
	>=xfce-base/libxfce4ui-4.10
	>=xfce-base/xfconf-4.10
	gnome-keyring? ( >=gnome-base/libgnome-keyring-2.22 )
	!xfce-base/xfce-utils"
RDEPEND="${COMMON_DEPEND}
	x11-apps/xrdb
	x11-misc/xdg-user-dirs
	consolekit? ( || ( sys-auth/consolekit >=sys-apps/systemd-40 ) )
	policykit? ( >=sys-auth/polkit-0.104-r1 )
	udev? ( >=sys-power/upower-0.9.15 )
	xscreensaver? ( || (
		>=x11-misc/xscreensaver-5.15
		gnome-extra/gnome-screensaver
		>=x11-misc/xlockmore-5.38
		>=x11-misc/slock-1
		) )"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	dev-util/pkgconfig
	sys-devel/gettext"

pkg_setup() {
	XFCONF=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
		$(use_enable gnome-keyring libgnome-keyring)
		$(xfconf_use_debug)
		)

	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
}

src_install() {
	xfconf_src_install

	local sessiondir=/etc/X11/Sessions
	echo startxfce4 > "${T}"/Xfce4
	exeinto ${sessiondir}
	doexe "${T}"/Xfce4
	dosym Xfce4 ${sessiondir}/Xfce
}