[gentoo-commits] gentoo-x86 commit in app-emulation/qemu-guest-agent: qemu-guest-agent-2.3.0.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/04/28 09:19:02

  Modified:             ChangeLog
  Added:                qemu-guest-agent-2.3.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.22                 app-emulation/qemu-guest-agent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	8 Apr 2015 07:30:31 -0000	1.21
+++ ChangeLog	28 Apr 2015 09:19:02 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/qemu-guest-agent
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog,v 1.21 2015/04/08 07:30:31 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog,v 1.22 2015/04/28 09:19:02 vapier Exp $
+
+*qemu-guest-agent-2.3.0 (28 Apr 2015)
+
+  28 Apr 2015; Mike Frysinger <vapier@g.o>
+  +qemu-guest-agent-2.3.0.ebuild:
+  Version bump.
 
   08 Apr 2015; Michał Górny <mgorny@g.o>
   qemu-guest-agent-1.5.2-r2.ebuild, qemu-guest-agent-1.6.0-r1.ebuild,



1.1                  app-emulation/qemu-guest-agent/qemu-guest-agent-2.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-guest-agent/qemu-guest-agent-2.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-guest-agent/qemu-guest-agent-2.3.0.ebuild?rev=1.1&content-type=text/plain

Index: qemu-guest-agent-2.3.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/qemu-guest-agent-2.3.0.ebuild,v 1.1 2015/04/28 09:19:02 vapier Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit eutils systemd udev python-r1

MY_PN="qemu"
MY_P="${MY_PN}-${PV}"

if [[ ${PV} == *9999* ]]; then
	EGIT_REPO_URI="git://git.qemu.org/qemu.git"
	inherit git-2
else
	SRC_URI="http://wiki.qemu.org/download/${MY_P}.tar.bz2"
	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
fi

DESCRIPTION="QEMU Guest Agent (qemu-ga) for use when running inside a VM"
HOMEPAGE="http://wiki.qemu.org/Features/QAPI/GuestAgent"

LICENSE="GPL-2 BSD-2"
SLOT="0"
IUSE=""

RDEPEND=">=dev-libs/glib-2.22
	!<app-emulation/qemu-1.1.1-r1
	!<sys-apps/sysvinit-2.88-r5"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch_user
}

src_configure() {
	python_setup

	tc-export AR LD OBJCOPY

	local myconf=(
		--prefix=/usr
		--sysconfdir=/etc
		--libdir="/usr/$(get_libdir)"
		--localstatedir=/
		--disable-bsd-user
		--disable-linux-user
		--disable-system
		--disable-strip
		--disable-werror
		--enable-guest-agent
		--python="${PYTHON}"
		--cc="$(tc-getCC)"
		--cxx="$(tc-getCXX)"
		--host-cc="$(tc-getBUILD_CC)"
	)
	echo "./configure ${myconf[*]}"
	./configure "${myconf[@]}" || die
}

src_compile() {
	emake V=1 qemu-ga
}

src_install() {
	dobin qemu-ga

	# Normal init stuff
	newinitd "${FILESDIR}/qemu-ga.init-r1" qemu-guest-agent
	newconfd "${FILESDIR}/qemu-ga.conf-r1" qemu-guest-agent

	insinto /etc/logrotate.d
	newins "${FILESDIR}/qemu-ga.logrotate" qemu-guest-agent

	# systemd stuff
	udev_newrules "${FILESDIR}/qemu-ga-systemd.udev" 99-qemu-guest-agent.rules

	systemd_newunit "${FILESDIR}/qemu-ga-systemd.service" \
		qemu-guest-agent.service
}

pkg_postinst() {
	elog "You should add 'qemu-guest-agent' to the default runlevel."
	elog "e.g. rc-update add qemu-guest-agent default"
}