[gentoo-commits] repo/gentoo:master commit in: dev-java/oracle-jre-bin/

[James Le Cuirot]

commit:     44061abc7b62901194533f2aff639e35964c508b
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 24 11:45:31 2017 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Wed Oct 25 20:05:45 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44061abc

dev-java/oracle-jre-bin: Remove vulnerable 1.8.0.144 wrt bug #635030

Package-Manager: Portage-2.3.12, Repoman-2.3.2

 dev-java/oracle-jre-bin/Manifest                   |   3 -
 .../oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild | 251 ---------------------
 2 files changed, 254 deletions(-)

diff --git a/dev-java/oracle-jre-bin/Manifest b/dev-java/oracle-jre-bin/Manifest
index 6d4cf2b7186..66f0f78bc37 100644
--- a/dev-java/oracle-jre-bin/Manifest
+++ b/dev-java/oracle-jre-bin/Manifest
@@ -1,5 +1,2 @@
-DIST jce_policy-8.zip 8409 SHA256 f3020a3922efd6626c2fff45695d527f34a8020e938a49292561f18ad1320b59 SHA512 abbaa81a35f904ec61b4cf3c2d1ca8c8d49e53bb248e698185eea906939d68f5063412800585ec74027aab1012ef189aebe1dc99fe8ef4230a0ecb0b527f88e5 WHIRLPOOL 8c9ce1ea4673b75fa6271b74e598880f98361d5d2c9c25439fa0af3d07cfeb871b39682dae4e38160f49770b1fec953162e451b9b2cf44d2c72a226944212bcc
-DIST jre-8u144-linux-i586.tar.gz 78658631 SHA256 9ac5b0d6cda9279a4959a6eb635d849d745a37dafc24666539d1c8f7d76ab77a SHA512 038e367fb00007e6b0f70ed3e48f318cfcb4144ef88b3a33d6c152cb186ede43622bc5d2fb40b39c695fdbe1fa735ab97f501a6ad0ed0a6cf48b286cc08e9ceb WHIRLPOOL 0bac95fc572bb1466b3f69c7e3dd03a77611366bc7c8076eb2feac41ecfde9a4aea6bb60b52b9db1dc0ec2bffcf553abe4ac4b1ffd28f7f3e1b6b71cd8ffc2fb
-DIST jre-8u144-linux-x64.tar.gz 75922776 SHA256 4e6e11aad54ae3c716a5607ee88d81f3f1e8b5b23ee474b0272dba351ee9f28a SHA512 fba5a5f5959746cb76a71847f5c6e3142816940d18c0022c0baf59611d43b24fae1052eeb217f09e840b5c393118260fb99dd38d1db7e74bb07ab0c34c2e1d60 WHIRLPOOL ac1921780076ff7ab5be5b942d5be0bab7fe12c027f1564b91734086d14c5a0da6b66d137034d7ee0318c4f72cb843013488591d1066a5f55c66dd4f53561a6f
 DIST jre-8u152-linux-i586.tar.gz 83131659 SHA256 1d0c9202fbed3136d46674547b92d467e28b6256dce5d1793c55c284c285a14d SHA512 8bd655ae97c333ed57991ed6d13d2c2647f85e5a1c853dd76031b8e7689db9a1b183bc665acc5b9f989139b34300ac65ab65c80e18234d6d1b06a4512fc4e542 WHIRLPOOL ea908a4efed078433cfb21ae6f015292ad0910e716e3f1a8748336e44484f0848dc317518e4fac04fd38aa6338f43b389c586b1cb6164639830f0024313688b7
 DIST jre-8u152-linux-x64.tar.gz 80061016 SHA256 ed04ffbf8050a69b15f02c51a2cae8e0de9362e7f6fe8995b1c39c613fc20ede SHA512 7c58ff2c3ac9af423ffab0ebfbfa7b4842072f6554569d76a99f8c82fa6935e36dbcf811f9c5510d71fc87db9520e684d877d99cae95f4874578ba42157ce85d WHIRLPOOL 7a3f4e34d70b4ccc850df754084448065c844973d77dec98ff57c2c8fa6338417b4e3f732995fcbc4e66cd8cbc34a2306aff11c4579749d66e33538c0d724682

diff --git a/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild b/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild
deleted file mode 100644
index 0829cfb55ff..00000000000
--- a/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild
+++ /dev/null
@@ -1,251 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit eutils java-vm-2 prefix versionator
-
-# This URIs need updating when bumping!
-JRE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jre8-downloads-2133155.html"
-JCE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jce8-download-2133166.html"
-
-if [[ "$(get_version_component_range 4)" == 0 ]] ; then
-	S_PV="$(get_version_component_range 1-3)"
-else
-	MY_PV_EXT="u$(get_version_component_range 4)"
-	S_PV="$(get_version_component_range 1-4)"
-fi
-
-MY_PV="$(get_version_component_range 2)${MY_PV_EXT}"
-
-AT_amd64="jre-${MY_PV}-linux-x64.tar.gz"
-AT_x86="jre-${MY_PV}-linux-i586.tar.gz"
-
-JCE_DIR="UnlimitedJCEPolicyJDK8"
-JCE_FILE="jce_policy-8.zip"
-
-DESCRIPTION="Oracle's Java SE Runtime Environment"
-HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
-SRC_URI="
-	amd64? ( ${AT_amd64} )
-	x86? ( ${AT_x86} )
-	jce? ( ${JCE_FILE} )"
-
-LICENSE="Oracle-BCLA-JavaSE"
-SLOT="1.8"
-KEYWORDS="amd64 x86"
-IUSE="alsa commercial cups +fontconfig headless-awt javafx jce nsplugin selinux"
-
-RESTRICT="fetch preserve-libs strip"
-QA_PREBUILT="*"
-
-# NOTES:
-#
-# * cups is dlopened.
-#
-# * libpng is also dlopened but only by libsplashscreen, which isn't
-#   important, so we can exclude that.
-#
-# * We still need to work out the exact AWT and JavaFX dependencies
-#   under MacOS. It doesn't appear to use many, if any, of the
-#   dependencies below.
-#
-RDEPEND="!x64-macos? (
-		!headless-awt? (
-			x11-libs/libX11
-			x11-libs/libXext
-			x11-libs/libXi
-			x11-libs/libXrender
-			x11-libs/libXtst
-		)
-		javafx? (
-			dev-libs/glib:2
-			dev-libs/libxml2:2
-			dev-libs/libxslt
-			media-libs/freetype:2
-			x11-libs/cairo
-			x11-libs/gtk+:2
-			x11-libs/libX11
-			x11-libs/libXtst
-			x11-libs/libXxf86vm
-			x11-libs/pango
-			virtual/opengl
-		)
-	)
-	alsa? ( media-libs/alsa-lib )
-	cups? ( net-print/cups )
-	fontconfig? ( media-libs/fontconfig:1.0 )
-	!prefix? ( sys-libs/glibc:* )
-	selinux? ( sec-policy/selinux-java )"
-
-DEPEND="app-arch/zip
-	jce? ( app-arch/unzip )"
-
-S="${WORKDIR}/jre"
-
-pkg_nofetch() {
-	local AT_ARCH="AT_${ARCH}"
-	local AT="${!AT_ARCH}"
-
-	einfo "Please download '${AT}' from:"
-	einfo "'${JRE_URI}'"
-	einfo "and move it to '${DISTDIR}'"
-
-	if use jce; then
-		einfo "Also download '${JCE_FILE}' from:"
-		einfo "'${JCE_URI}'"
-		einfo "and move it to '${DISTDIR}'"
-	fi
-
-	einfo
-	einfo "If the above mentioned urls do not point to the correct version anymore,"
-	einfo "please download the files from Oracle's java download archive:"
-	einfo
-	einfo "   http://www.oracle.com/technetwork/java/javase/downloads/java-archive-javase8-2177648.html#jre-${MY_PV}-oth-JPR"
-	einfo
-
-}
-
-src_unpack() {
-	default
-
-	# Upstream is changing their versioning scheme every release around 1.8.0.*;
-	# to stop having to change it over and over again, just wildcard match and
-	# live a happy life instead of trying to get this new jre1.8.0_05 to work.
-	mv "${WORKDIR}"/jre* "${S}" || die
-}
-
-src_prepare() {
-	if use jce ; then
-		mv "${WORKDIR}"/${JCE_DIR} lib/security/ || die
-	fi
-
-	default
-
-	# Remove the hook that calls Oracle's evil usage tracker. Not just
-	# because it's evil but because it breaks the sandbox during builds
-	# and we can't find any other feasible way to disable it or make it
-	# write somewhere else. See bug #559936 for details.
-	zip -d lib/rt.jar sun/misc/PostVMInitHook.class || die
-}
-
-src_install() {
-	local dest="/opt/${P}"
-	local ddest="${ED}${dest#/}"
-
-	# Create files used as storage for system preferences.
-	mkdir .systemPrefs || die
-	touch .systemPrefs/.system.lock || die
-	touch .systemPrefs/.systemRootModFile || die
-
-	if ! use alsa ; then
-		rm -vf lib/*/libjsoundalsa.* || die
-	fi
-
-	if ! use commercial; then
-		rm -vfr lib/jfr* || die
-	fi
-
-	if use headless-awt ; then
-		rm -vf lib/*/lib*{[jx]awt,splashscreen}* \
-		   bin/{javaws,policytool} || die
-	fi
-
-	if ! use javafx ; then
-		rm -vf lib/*/lib*{decora,fx,glass,prism}* \
-		   lib/*/libgstreamer-lite.* lib/{,ext/}*fx* || die
-	fi
-
-	if ! use nsplugin ; then
-		rm -vf lib/*/libnpjp2.* || die
-	else
-		local nsplugin=$(echo lib/*/libnpjp2.*)
-	fi
-
-	# Even though plugins linked against multiple ffmpeg versions are
-	# provided, they generally lag behind what Gentoo has available.
-	rm -vf lib/*/libavplugin* || die
-
-	dodoc COPYRIGHT
-	dodir "${dest}"
-	cp -pPR	bin lib man "${ddest}" || die
-
-	if use jce ; then
-		dodir ${dest}/lib/security/strong-jce
-		mv "${ddest}"/lib/security/US_export_policy.jar \
-			"${ddest}"/lib/security/strong-jce || die
-		mv "${ddest}"/lib/security/local_policy.jar \
-			"${ddest}"/lib/security/strong-jce || die
-		dosym "${dest}"/lib/security/${JCE_DIR}/US_export_policy.jar \
-			"${dest}"/lib/security/US_export_policy.jar
-		dosym "${dest}"/lib/security/${JCE_DIR}/local_policy.jar \
-			"${dest}"/lib/security/local_policy.jar
-	fi
-
-	if use nsplugin ; then
-		local nsplugin_link=${nsplugin##*/}
-		nsplugin_link=${nsplugin_link/./-${PN}-${SLOT}.}
-		dosym "${dest}/${nsplugin}" "/usr/$(get_libdir)/nsbrowser/plugins/${nsplugin_link}"
-	fi
-
-	# Install desktop file for the Java Control Panel.
-	# Using ${PN}-${SLOT} to prevent file collision with jre and or other slots.
-	# make_desktop_entry can't be used as ${P} would end up in filename.
-	newicon lib/desktop/icons/hicolor/48x48/apps/sun-jcontrol.png \
-		sun-jcontrol-${PN}-${SLOT}.png || die
-	sed -e "s#Name=.*#Name=Java Control Panel for Oracle JRE ${SLOT}#" \
-		-e "s#Exec=.*#Exec=/opt/${P}/bin/jcontrol#" \
-		-e "s#Icon=.*#Icon=sun-jcontrol-${PN}-${SLOT}#" \
-		-e "s#Application;##" \
-		-e "/Encoding/d" \
-		lib/desktop/applications/sun_java.desktop > \
-		"${T}"/jcontrol-${PN}-${SLOT}.desktop || die
-	domenu "${T}"/jcontrol-${PN}-${SLOT}.desktop
-
-	# Prune all fontconfig files so libfontconfig will be used and only install
-	# a Gentoo specific one if fontconfig is disabled.
-	# http://docs.oracle.com/javase/8/docs/technotes/guides/intl/fontconfig.html
-	rm "${ddest}"/lib/fontconfig.* || die
-	if ! use fontconfig ; then
-		cp "${FILESDIR}"/fontconfig.Gentoo.properties "${T}"/fontconfig.properties || die
-		eprefixify "${T}"/fontconfig.properties
-		insinto "${dest}"/lib/
-		doins "${T}"/fontconfig.properties
-	fi
-
-	# This needs to be done before CDS - #215225
-	java-vm_set-pax-markings "${ddest}"
-
-	# see bug #207282
-	einfo "Creating the Class Data Sharing archives"
-	case ${ARCH} in
-		arm|ia64)
-			${ddest}/bin/java -client -Xshare:dump || die
-			;;
-		x86)
-			${ddest}/bin/java -client -Xshare:dump || die
-			# limit heap size for large memory on x86 #467518
-			# this is a workaround and shouldn't be needed.
-			${ddest}/bin/java -server -Xms64m -Xmx64m -Xshare:dump || die
-			;;
-		*)
-			${ddest}/bin/java -server -Xshare:dump || die
-			;;
-	esac
-
-	# Remove empty dirs we might have copied.
-	find "${D}" -type d -empty -exec rmdir -v {} + || die
-
-	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
-	java-vm_revdep-mask
-	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
-}
-
-pkg_postinst() {
-	java-vm-2_pkg_postinst
-
-	if ! use headless-awt && ! use javafx; then
-		ewarn "You have disabled the javafx flag. Some modern desktop Java applications"
-		ewarn "require this and they may fail with a confusing error message."
-	fi
-}