[gentoo-commits] repo/gentoo:master commit in: dev-ruby/coolio/

[Hans de Graaff]

commit:     cb1ba7c26b4dfe06a411da0153c5e04843c89d44
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 27 05:51:53 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Wed Oct 27 11:24:49 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb1ba7c2

dev-ruby/coolio: add ruby30

Switch to bundled iobuffer since the upstream version by the same author
it no longer maintained and does not work with ruby30.

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/coolio/coolio-1.7.1-r1.ebuild | 44 ++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-ruby/coolio/coolio-1.7.1-r1.ebuild b/dev-ruby/coolio/coolio-1.7.1-r1.ebuild
new file mode 100644
index 00000000000..b7f9b1eec0b
--- /dev/null
+++ b/dev-ruby/coolio/coolio-1.7.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby25 ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+RUBY_FAKEGEM_NAME="cool.io"
+
+RUBY_FAKEGEM_GEMSPEC="cool.io.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/cool.io/extconf.rb ext/iobuffer/extconf.rb)
+
+inherit ruby-fakegem
+
+DESCRIPTION="A high performance event framework for Ruby which uses the libev C library"
+HOMEPAGE="https://coolio.github.io/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# cool.io includes a bundled version of libev that is patched to work correctly with ruby.
+
+all_ruby_prepare() {
+	rm -r Gemfile* lib/.gitignore || die
+
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+	sed -i -e '28i  s.add_dependency "iobuffer"' ${RUBY_FAKEGEM_GEMSPEC} || die
+	sed -i -e '/git ls-files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Avoid dependency on rake-compiler
+	sed -i -e '/extensiontask/ s:^:#:' \
+		-e '/ExtensionTask/,/^end/ s:^:#:' Rakefile || die
+
+	# Remove specs that require network connectivity
+	rm -f spec/dns_spec.rb || die
+
+	# Use one address consistently
+	sed -i -e 's/localhost/127.0.0.1/' spec/{udp_socket,tcp_server,iobuffer}_spec.rb || die
+}