[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfconf/

[Michał Górny]

commit:     4491110b5f5bfc9b53519c88a7b189591b2a521d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May  6 15:01:27 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May  6 15:34:32 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4491110b

xfce-base/xfconf: Bump to 4.14.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfconf/Manifest             |  1 +
 xfce-base/xfconf/xfconf-4.14.3.ebuild | 87 +++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/xfce-base/xfconf/Manifest b/xfce-base/xfconf/Manifest
index be5a6bf5e02..9355eef3900 100644
--- a/xfce-base/xfconf/Manifest
+++ b/xfce-base/xfconf/Manifest
@@ -1 +1,2 @@
 DIST xfconf-4.14.1.tar.bz2 644804 BLAKE2B 1b04770fa9b3f4901f561bc3978dd7ffdbfea9496330a98334ffb19c0c7413b0540423f20200e2e5191ff876f3e2c32ca8354bbab70aac4de00592d995f77e72 SHA512 727d013f7e71e0eb9ff17e464acd65c1fa507f8eba1bd29621dae070161042f60f47b8ac048b28849bf45232d04d5d6e48530aa0bd1e661a3f58db47703a8808
+DIST xfconf-4.14.3.tar.bz2 591432 BLAKE2B 9722547018a6db7132bad53b750ec8bd66b2f5dde2348b605bf9a6ce6a7d18fefbfb16c31f58c1c4e6c593d3f0525c3bd8231b4bab0728bd64f91d918f0a6c23 SHA512 e3add05018215cc597bb76d852903077e1fd0a21429c462116c560739eaf32167f9dddac3adb36e89b9380b87fc4b4c38d4ee9fdd5139b540268be437fc3a713

diff --git a/xfce-base/xfconf/xfconf-4.14.3.ebuild b/xfce-base/xfconf/xfconf-4.14.3.ebuild
new file mode 100644
index 00000000000..6cdd92555cd
--- /dev/null
+++ b/xfce-base/xfconf/xfconf-4.14.3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala
+
+DESCRIPTION="A configuration management system for Xfce"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="debug introspection perl vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.42
+	>=xfce-base/libxfce4util-4.10:=
+	introspection? ( dev-libs/gobject-introspection:= )
+	perl? (
+		dev-lang/perl:=[-build(-)]
+		dev-perl/glib-perl
+	)
+	!<xfce-base/xfce4-panel-4.13.1
+	!<xfce-base/xfce4-settings-4.13.1"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+	perl? (
+		dev-perl/ExtUtils-Depends
+		dev-perl/ExtUtils-PkgConfig
+	)
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable perl perl-bindings)
+		$(use_enable introspection)
+		$(use_enable vala)
+		$(use_enable debug checks)
+		--with-perl-options=INSTALLDIRS=vendor
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	local service_dir=${HOME}/.local/share/dbus-1/services
+	mkdir -p "${service_dir}" || die
+	cat > "${service_dir}/org.xfce.Xfconf.service" <<-EOF || die
+		[D-BUS Service]
+		Name=org.xfce.Xfconf
+		Exec=${S}/xfconfd/xfconfd
+	EOF
+
+	(
+		# start isolated dbus session bus
+		dbus_data=$(dbus-launch --sh-syntax) || exit
+		eval "${dbus_data}"
+
+		nonfatal emake check
+		ret=${?}
+
+		kill "${DBUS_SESSION_BUS_PID}"
+		exit "${ret}"
+	) || die
+}
+
+src_install() {
+	default
+	find "${D}" -type f -name '*.la' -delete || die
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -delete || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -delete || die
+	fi
+}