Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Davide Pesavento (pesa)" <pesa@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in dev-util/eric: eric-4.5.0.ebuild eric-5.2.0.ebuild ChangeLog
Date: Tue, 28 Feb 2012 15:00:08
Message-Id: 20120228145958.8DEB720034@flycatcher.gentoo.org
1 pesa 12/02/28 14:59:58
2
3 Modified: ChangeLog
4 Added: eric-4.5.0.ebuild eric-5.2.0.ebuild
5 Log:
6 Version bumps.
7
8 (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)
9
10 Revision Changes Path
11 1.167 dev-util/eric/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.167&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?rev=1.167&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/ChangeLog?r1=1.166&r2=1.167
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v
20 retrieving revision 1.166
21 retrieving revision 1.167
22 diff -u -r1.166 -r1.167
23 --- ChangeLog 1 Jan 2012 22:54:42 -0000 1.166
24 +++ ChangeLog 28 Feb 2012 14:59:58 -0000 1.167
25 @@ -1,6 +1,13 @@
26 # ChangeLog for dev-util/eric
27 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.166 2012/01/01 22:54:42 pesa Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.167 2012/02/28 14:59:58 pesa Exp $
30 +
31 +*eric-4.5.0 (28 Feb 2012)
32 +*eric-5.2.0 (28 Feb 2012)
33 +
34 + 28 Feb 2012; Davide Pesavento <pesa@g.o> +eric-4.5.0.ebuild,
35 + +eric-5.2.0.ebuild:
36 + Version bumps.
37
38 *eric-4.4.19 (01 Jan 2012)
39 *eric-5.1.7 (01 Jan 2012)
40
41
42
43 1.1 dev-util/eric/eric-4.5.0.ebuild
44
45 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.0.ebuild?rev=1.1&view=markup
46 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-4.5.0.ebuild?rev=1.1&content-type=text/plain
47
48 Index: eric-4.5.0.ebuild
49 ===================================================================
50 # Copyright 1999-2012 Gentoo Foundation
51 # Distributed under the terms of the GNU General Public License v2
52 # $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-4.5.0.ebuild,v 1.1 2012/02/28 14:59:58 pesa Exp $
53
54 EAPI="4"
55 PYTHON_DEPEND="2:2.6"
56 SUPPORT_PYTHON_ABIS="1"
57 # 2.4 and 2.5 are restricted to avoid conditional dependency on dev-python/simplejson.
58 RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython 2.7-pypy-*"
59
60 inherit eutils python
61
62 SLOT="4"
63 MY_PN="${PN}${SLOT}"
64 MY_PV="${PV/_pre/-snapshot-}"
65 MY_P="${MY_PN}-${MY_PV}"
66
67 DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
68 HOMEPAGE="http://eric-ide.python-projects.org/"
69 BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
70 SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
71
72 LICENSE="GPL-3"
73 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
74 IUSE="kde spell"
75
76 DEPEND="
77 >=dev-python/sip-4.12.4
78 >=dev-python/PyQt4-4.6[assistant,svg,webkit,X]
79 >=dev-python/qscintilla-python-2.3
80 kde? ( kde-base/pykde4 )
81 "
82 RDEPEND="${DEPEND}
83 >=dev-python/chardet-2.0.1
84 >=dev-python/coverage-3.0.1
85 >=dev-python/pygments-1.3.1
86 "
87 PDEPEND="
88 spell? ( dev-python/pyenchant )
89 "
90
91 LANGS="cs de en es fr it ru tr zh_CN"
92 for L in ${LANGS}; do
93 SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
94 IUSE+=" linguas_${L}"
95 done
96 unset L
97
98 S=${WORKDIR}/${MY_P}
99
100 PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
101
102 src_prepare() {
103 epatch "${FILESDIR}/eric-4.4-no-interactive.patch"
104 use kde || epatch "${FILESDIR}/eric-4.4-no-pykde.patch"
105
106 # Delete internal copies of dev-python/chardet, dev-python/coverage,
107 # dev-python/pygments and dev-python/simplejson.
108 rm -fr eric/ThirdParty
109 rm -fr eric/DebugClients/Python{,3}/coverage
110 sed -i -e '\|/coverage/|d' eric/${MY_PN}.e4p || die
111 sed -i -e 's/from DebugClients\.Python3\?\.coverage /from coverage /' \
112 $(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
113 }
114
115 src_install() {
116 installation() {
117 "$(PYTHON)" install.py \
118 -z \
119 -b "${EPREFIX}/usr/bin" \
120 -i "${T}/images/${PYTHON_ABI}" \
121 -d "${EPREFIX}$(python_get_sitedir)" \
122 -c
123 }
124 python_execute_function installation
125 python_merge_intermediate_installation_images "${T}/images"
126
127 doicon eric/icons/default/eric.png || die
128 make_desktop_entry "${MY_PN} --nosplash" ${MY_PN} eric "Development;IDE;Qt"
129 }
130
131 pkg_postinst() {
132 python_mod_optimize ${MY_PN}{,config.py,plugins}
133
134 elog
135 elog "If you want to use Eric with mod_python, have a look at"
136 elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
137 elog
138 elog "The following packages will give Eric extended functionality:"
139 elog " dev-python/pylint"
140 elog " dev-python/pysvn"
141 elog
142 elog "This version has a plugin interface with plugin-autofetch from"
143 elog "the application itself. You may want to check those as well."
144 elog
145 }
146
147 pkg_postrm() {
148 python_mod_cleanup ${MY_PN}{,config.py,plugins}
149 }
150
151
152
153 1.1 dev-util/eric/eric-5.2.0.ebuild
154
155 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.2.0.ebuild?rev=1.1&view=markup
156 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/eric/eric-5.2.0.ebuild?rev=1.1&content-type=text/plain
157
158 Index: eric-5.2.0.ebuild
159 ===================================================================
160 # Copyright 1999-2012 Gentoo Foundation
161 # Distributed under the terms of the GNU General Public License v2
162 # $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-5.2.0.ebuild,v 1.1 2012/02/28 14:59:58 pesa Exp $
163
164 EAPI="4"
165 PYTHON_DEPEND="3:3.1"
166 SUPPORT_PYTHON_ABIS="1"
167 RESTRICT_PYTHON_ABIS="2.* *-jython 2.7-pypy-*"
168
169 inherit eutils python
170
171 SLOT="5"
172 MY_PN="${PN}${SLOT}"
173 MY_PV="${PV/_pre/-snapshot-}"
174 MY_P="${MY_PN}-${MY_PV}"
175
176 DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
177 HOMEPAGE="http://eric-ide.python-projects.org/"
178 BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
179 SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
180
181 LICENSE="GPL-3"
182 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
183 IUSE="spell"
184
185 DEPEND="
186 >=dev-python/sip-4.12.4
187 >=dev-python/PyQt4-4.8[assistant,svg,webkit,X]
188 >=dev-python/qscintilla-python-2.4
189 "
190 RDEPEND="${DEPEND}
191 >=dev-python/chardet-2.0.1
192 >=dev-python/coverage-3.2
193 >=dev-python/pygments-1.4
194 "
195 PDEPEND="
196 spell? ( dev-python/pyenchant )
197 "
198
199 LANGS="cs de en es fr it ru tr zh_CN"
200 for L in ${LANGS}; do
201 SRC_URI+=" linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
202 IUSE+=" linguas_${L}"
203 done
204 unset L
205
206 S=${WORKDIR}/${MY_P}
207
208 PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
209
210 src_prepare() {
211 # Avoid file collisions between different slots of Eric.
212 sed -e "s/^Icon=eric$/&${SLOT}/" -i eric/${MY_PN}.desktop || die
213 sed -e "s/\([^[:alnum:]]\)eric\.png\([^[:alnum:]]\)/\1eric5.png\2/" \
214 -i $(grep -lr "eric\.png" .) || die
215 mv eric/icons/default/eric{,5}.png || die
216 mv eric/pixmaps/eric{,5}.png || die
217 rm -f eric/APIs/Python/zope-*.api
218 rm -f eric/APIs/Ruby/Ruby-*.api
219
220 # Delete internal copies of dev-python/chardet,
221 # dev-python/coverage and dev-python/pygments.
222 rm -fr eric/ThirdParty
223 rm -fr eric/DebugClients/Python{,3}/coverage
224 sed -i -e '\|/coverage/|d' eric/${MY_PN}.e4p || die
225 sed -i -e 's/from DebugClients\.Python3\?\.coverage /from coverage /' \
226 $(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
227 }
228
229 src_install() {
230 installation() {
231 "$(PYTHON)" install.py \
232 -z \
233 -b "${EPREFIX}/usr/bin" \
234 -i "${T}/images/${PYTHON_ABI}" \
235 -d "${EPREFIX}$(python_get_sitedir)" \
236 -c
237 }
238 python_execute_function installation
239 python_merge_intermediate_installation_images "${T}/images"
240
241 doicon eric/icons/default/${MY_PN}.png || die
242 }
243
244 pkg_postinst() {
245 python_mod_optimize -x "/eric5/(DebugClients/Python|UtilitiesPython2)/" ${MY_PN}{,config.py,plugins}
246
247 elog
248 elog "If you want to use Eric with mod_python, have a look at"
249 elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
250 elog
251 elog "The following packages will give Eric extended functionality:"
252 elog " dev-python/pylint"
253 elog " dev-python/pysvn"
254 elog
255 elog "This version has a plugin interface with plugin-autofetch from"
256 elog "the application itself. You may want to check those as well."
257 elog
258 }
259
260 pkg_postrm() {
261 python_mod_cleanup ${MY_PN}{,config.py,plugins}
262 }
Report Message
Find on MARC Find on Google Groups