[gentoo-commits] gentoo-x86 commit in net-firewall/conntrack-tools: conntrack-tools-0.9.12.ebuild ChangeLog

[Peter Volkov (pva)]

pva         09/04/03 10:27:11

  Modified:             ChangeLog
  Added:                conntrack-tools-0.9.12.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc28/cvs/Linux i686)

Revision  Changes    Path
1.30                 net-firewall/conntrack-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	8 Mar 2009 13:47:44 -0000	1.29
+++ ChangeLog	3 Apr 2009 10:27:10 -0000	1.30
@@ -1,6 +1,11 @@
 # ChangeLog for net-firewall/conntrack-tools
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v 1.29 2009/03/08 13:47:44 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v 1.30 2009/04/03 10:27:10 pva Exp $
+
+*conntrack-tools-0.9.12 (03 Apr 2009)
+
+  03 Apr 2009; Peter Volkov <pva@g.o> +conntrack-tools-0.9.12.ebuild:
+  Version bump.
 
   08 Mar 2009; Peter Volkov <pva@g.o>
   +files/conntrack-tools-0.9.11-INT_MAX.patch,



1.1                  net-firewall/conntrack-tools/conntrack-tools-0.9.12.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-0.9.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-0.9.12.ebuild?rev=1.1&content-type=text/plain

Index: conntrack-tools-0.9.12.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-0.9.12.ebuild,v 1.1 2009/04/03 10:27:10 pva Exp $

EAPI="2"
inherit linux-info eutils

DESCRIPTION="Connection tracking userspace tools"
HOMEPAGE="http://conntrack-tools.netfilter.org"
SRC_URI="http://www.netfilter.org/projects/conntrack-tools/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~sparc ~x86"
IUSE=""

RDEPEND="
	>=net-libs/libnfnetlink-0.0.40
	>=net-libs/libnetfilter_conntrack-0.0.99
	!net-firewall/conntrack"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0"

pkg_setup() {
	linux-info_pkg_setup

	if kernel_is lt 2 6 18 ; then
		die "${PN} requires at least 2.6.18 kernel version"
	fi

	#netfilter core team has changed some option names with kernel 2.6.20
	if kernel_is lt 2 6 20 ; then
		CONFIG_CHECK="IP_NF_CONNTRACK_NETLINK"
	else
		CONFIG_CHECK="NF_CT_NETLINK"
	fi
	CONFIG_CHECK="${CONFIG_CHECK} NF_CONNTRACK NF_CONNTRACK_IPV4
		NETFILTER_NETLINK NF_CONNTRACK_EVENTS"

	check_extra_config
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	newinitd "${FILESDIR}/conntrackd.initd-r1" conntrackd || die
	newconfd "${FILESDIR}/conntrackd.confd-r1" conntrackd || die

	insinto /etc/conntrackd
	doins doc/stats/conntrackd.conf || die

	dodoc AUTHORS ChangeLog || die
	insinto /usr/share/doc/${PF}
	doins -r doc/* || die
}