[gentoo-commits] gentoo-x86 commit in net-voip/yate: yate-9999.ebuild yate-5.3.0.ebuild ChangeLog

[Richard Farina (zerochaos)]

zerochaos    14/07/25 20:12:38

  Modified:             yate-9999.ebuild ChangeLog
  Added:                yate-5.3.0.ebuild
  Log:
  ebuild cleanup, QA warnings fix, adding stable version
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)

Revision  Changes    Path
1.4                  net-voip/yate/yate-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/yate-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/yate-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/yate-9999.ebuild?r1=1.3&r2=1.4

Index: yate-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/yate/yate-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- yate-9999.ebuild	28 Apr 2014 02:40:27 -0000	1.3
+++ yate-9999.ebuild	25 Jul 2014 20:12:38 -0000	1.4
@@ -1,19 +1,27 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/yate-9999.ebuild,v 1.3 2014/04/28 02:40:27 zx2c4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/yate-9999.ebuild,v 1.4 2014/07/25 20:12:38 zerochaos Exp $
 
 EAPI=5
 
-inherit subversion autotools
+inherit autotools eutils
 
 DESCRIPTION="The Yate AV Suite"
 HOMEPAGE="http://yate.null.ro/"
-ESVN_REPO_URI="http://voip.null.ro/svn/yate/trunk"
+
+if [[ ${PV} == 9999 ]] ; then
+	ESVN_REPO_URI="http://voip.null.ro/svn/yate/trunk"
+	inherit subversion
+	KEYWORDS=""
+else
+	SRC_URI="http://voip.null.ro/tarballs/${PN}5/${P}-1.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}"
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
-IUSE="sse2 sctp dahdi zaptel wpcard tdmcard wanpipe +ilbc +ilbc-webrtc +isac-float isac-fixed postgres mysql +gsm +speex h323 spandsp +ssl qt4 +zlib amrnb"
+IUSE="doc sse2 sctp dahdi zaptel wpcard tdmcard wanpipe +ilbc +ilbc-webrtc +isac-float isac-fixed postgres mysql +gsm +speex h323 spandsp +ssl qt4 +zlib amrnb"
 
 RDEPEND="
 	postgres? ( dev-db/postgresql-base )
@@ -28,9 +36,12 @@
 	spandsp? ( >=media-libs/spandsp-0.0.3 )
 	dahdi? ( net-misc/dahdi )
 "
-DEPEND="app-doc/doxygen virtual/pkgconfig ${RDEPEND}"
+DEPEND="doc? ( || ( app-doc/doxygen dev-util/kdoc ) )
+	virtual/pkgconfig
+	${RDEPEND}"
 
 src_prepare() {
+	epatch "${FILESDIR}"/dont-mess-with-cflags.patch
 	eautoreconf
 	./yate-config.sh || die
 }
@@ -70,3 +81,11 @@
 src_compile() {
 	emake -j1
 }
+
+src_install() {
+	if use doc; then
+		emake DESTDIR="${ED}" install
+	else
+		emake DESTDIR="${ED}" install-noapi
+	fi
+}



1.29                 net-voip/yate/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	28 Apr 2014 05:21:17 -0000	1.28
+++ ChangeLog	25 Jul 2014 20:12:38 -0000	1.29
@@ -1,6 +1,15 @@
 # ChangeLog for net-voip/yate
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v 1.28 2014/04/28 05:21:17 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v 1.29 2014/07/25 20:12:38 zerochaos Exp $
+
+*yate-5.3.0 (25 Jul 2014)
+
+  25 Jul 2014; Rick Farina <zerochaos@g.o>
+  +files/dont-mess-with-cflags.patch, +yate-5.3.0.ebuild,
+  -files/yate-2.0.0-as-needed.patch, -files/yate-2.0.0-cxxflags.patch,
+  -files/yate-2.0.0-ilbc-alsa-oss.patch, -files/yate-2.0.0-spandsp.patch,
+  -files/yate-4.3.0-ilbc-alsa-oss.patch, yate-9999.ebuild:
+  ebuild cleanup, QA warnings fix, adding stable version
 
   28 Apr 2014; Patrick Lauer <patrick@g.o> metadata.xml:
   Remove unneeded useflag description from metadata.xml



1.1                  net-voip/yate/yate-5.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/yate-5.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/yate/yate-5.3.0.ebuild?rev=1.1&content-type=text/plain

Index: yate-5.3.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/yate-5.3.0.ebuild,v 1.1 2014/07/25 20:12:38 zerochaos Exp $

EAPI=5

inherit autotools eutils

DESCRIPTION="The Yate AV Suite"
HOMEPAGE="http://yate.null.ro/"

if [[ ${PV} == 9999 ]] ; then
	ESVN_REPO_URI="http://voip.null.ro/svn/yate/trunk"
	inherit subversion
	KEYWORDS=""
else
	SRC_URI="http://voip.null.ro/tarballs/${PN}5/${P}-1.tar.gz"
	KEYWORDS="~amd64 ~x86"
	S="${WORKDIR}/${PN}"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="doc sse2 sctp dahdi zaptel wpcard tdmcard wanpipe +ilbc +ilbc-webrtc +isac-float isac-fixed postgres mysql +gsm +speex h323 spandsp +ssl qt4 +zlib amrnb"

RDEPEND="
	postgres? ( dev-db/postgresql-base )
	mysql? ( virtual/mysql )
	gsm? ( media-sound/gsm )
	speex? ( media-libs/speex )
	ssl? ( dev-libs/openssl )
	h323? ( net-libs/h323plus )
	zlib? ( sys-libs/zlib )
	qt4? ( dev-qt/qtgui:4 dev-qt/designer:4 )
	ilbc? ( dev-libs/ilbc-rfc3951 )
	spandsp? ( >=media-libs/spandsp-0.0.3 )
	dahdi? ( net-misc/dahdi )
"
DEPEND="doc? ( || ( app-doc/doxygen dev-util/kdoc ) )
	virtual/pkgconfig
	${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/dont-mess-with-cflags.patch
	eautoreconf
	./yate-config.sh || die
}

#fdsize, inline, rtti: keep default values
#internalregex: use system
#coredumper: not in the tree, bug 118716
#wanpipe, wphwec: not in the tree, bug 188939
#amrnb: not in tree!
#zaptel: ??
src_configure() {
	econf \
		--with-archlib=$(get_libdir) \
		$(use_enable sse2) \
		$(use_enable sctp) \
		$(use_enable dahdi) \
		$(use_enable zaptel) \
		$(use_enable wpcard) \
		$(use_enable tdmcard) \
		$(use_enable wanpipe) \
		$(use_enable ilbc) \
		$(use_enable ilbc-webrtc) \
		$(use_enable isac-float) \
		$(use_enable isac-fixed) \
		$(use_with postgres libpq) \
		$(use_with mysql) \
		$(use_with gsm libgsm) \
		$(use_with speex libspeex) \
		$(use_with amrnb) \
		$(use_with spandsp) \
		$(use_with h323 openh323 /usr) \
		$(use_with h323 pwlib /usr) \
		$(use_with ssl openssl) \
		$(use_with qt4 libqt4)
}

src_compile() {
	emake -j1
}

src_install() {
	if use doc; then
		emake DESTDIR="${ED}" install
	else
		emake DESTDIR="${ED}" install-noapi
	fi
}