[gentoo-commits] gentoo-x86 commit in sys-devel/gdb: ChangeLog gdb-7.2.50.20101117.4.15.ebuild gdb-7.2.ebuild

[Mike Frysinger (vapier)]

vapier      10/12/31 21:06:29

  Modified:             ChangeLog gdb-7.2.ebuild
  Added:                gdb-7.2.50.20101117.4.15.ebuild
  Log:
  Merge rpm and non-rpm ebuilds, and version bump the rpm one.
  
  (Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

Revision  Changes    Path
1.175                sys-devel/gdb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/ChangeLog?r1=1.174&r2=1.175

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/gdb/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog	14 Sep 2010 00:35:34 -0000	1.174
+++ ChangeLog	31 Dec 2010 21:06:28 -0000	1.175
@@ -1,6 +1,12 @@
 # ChangeLog for sys-devel/gdb
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/ChangeLog,v 1.174 2010/09/14 00:35:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/ChangeLog,v 1.175 2010/12/31 21:06:28 vapier Exp $
+
+*gdb-7.2.50.20101117.4.15 (31 Dec 2010)
+
+  31 Dec 2010; Mike Frysinger <vapier@g.o> gdb-7.2.ebuild,
+  +gdb-7.2.50.20101117.4.15.ebuild:
+  Merge rpm and non-rpm ebuilds, and version bump the rpm one.
 
   14 Sep 2010; Mike Frysinger <vapier@g.o> gdb-7.2.ebuild:
   Fix EAPI=3 porting and force usage of python-2 by Arfrever Frehtes Taifersar



1.4                  sys-devel/gdb/gdb-7.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild?r1=1.3&r2=1.4

Index: gdb-7.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- gdb-7.2.ebuild	14 Sep 2010 00:35:34 -0000	1.3
+++ gdb-7.2.ebuild	31 Dec 2010 21:06:28 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild,v 1.3 2010/09/14 00:35:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/gdb-7.2.ebuild,v 1.4 2010/12/31 21:06:28 vapier Exp $
 
 EAPI="3"
 
@@ -14,12 +14,27 @@
 fi
 is_cross() { [[ ${CHOST} != ${CTARGET} ]] ; }
 
+if [[ ${PV} == *.*.*.*.*.* ]] ; then
+	inherit versionator rpm
+	# fedora version: gdb-6.8.50.20090302-8.fc11.src.rpm
+	gvcr() { get_version_component_range "$@"; }
+	MY_PV=$(gvcr 1-4)
+	RPM="${PN}-${MY_PV}-$(gvcr 5).fc$(gvcr 6).src.rpm"
+else
+	MY_PV=${PV}
+	RPM=
+fi
+
 PATCH_VER="1"
 DESCRIPTION="GNU debugger"
 HOMEPAGE="http://sources.redhat.com/gdb/"
-SRC_URI="http://ftp.gnu.org/gnu/gdb/${P}.tar.bz2
-	ftp://sources.redhat.com/pub/gdb/releases/${P}.tar.bz2
-	${PATCH_VER:+mirror://gentoo/${P}-patches-${PATCH_VER}.tar.xz}"
+if [[ -n ${RPM} ]] ; then
+	SRC_URI="http://mirrors.kernel.org/fedora/development/source/SRPMS/${RPM}"
+else
+	SRC_URI="http://ftp.gnu.org/gnu/gdb/${P}.tar.bz2
+		ftp://sources.redhat.com/pub/gdb/releases/${P}.tar.bz2"
+fi
+SRC_URI="${SRC_URI} ${PATCH_VER:+mirror://gentoo/${P}-patches-${PATCH_VER}.tar.xz}"
 
 LICENSE="GPL-2 LGPL-2"
 is_cross \
@@ -37,7 +52,10 @@
 	test? ( dev-util/dejagnu )
 	nls? ( sys-devel/gettext )"
 
+S=${WORKDIR}/${PN}-${MY_PV}
+
 src_prepare() {
+	[[ -n ${RPM} ]] && rpm_spec_epatch "${WORKDIR}"/gdb.spec
 	use vanilla || [[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/patch
 	strip-linguas -u bfd/po opcodes/po
 }



1.1                  sys-devel/gdb/gdb-7.2.50.20101117.4.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/gdb-7.2.50.20101117.4.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/gdb/gdb-7.2.50.20101117.4.15.ebuild?rev=1.1&content-type=text/plain

Index: gdb-7.2.50.20101117.4.15.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/gdb-7.2.50.20101117.4.15.ebuild,v 1.1 2010/12/31 21:06:28 vapier Exp $

EAPI="3"

inherit flag-o-matic eutils

export CTARGET=${CTARGET:-${CHOST}}
if [[ ${CTARGET} == ${CHOST} ]] ; then
	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
		export CTARGET=${CATEGORY/cross-}
	fi
fi
is_cross() { [[ ${CHOST} != ${CTARGET} ]] ; }

if [[ ${PV} == *.*.*.*.*.* ]] ; then
	inherit versionator rpm
	# fedora version: gdb-6.8.50.20090302-8.fc11.src.rpm
	gvcr() { get_version_component_range "$@"; }
	MY_PV=$(gvcr 1-4)
	RPM="${PN}-${MY_PV}-$(gvcr 5).fc$(gvcr 6).src.rpm"
else
	MY_PV=${PV}
	RPM=
fi

PATCH_VER=""
DESCRIPTION="GNU debugger"
HOMEPAGE="http://sources.redhat.com/gdb/"
if [[ -n ${RPM} ]] ; then
	SRC_URI="http://mirrors.kernel.org/fedora/development/source/SRPMS/${RPM}"
else
	SRC_URI="http://ftp.gnu.org/gnu/gdb/${P}.tar.bz2
		ftp://sources.redhat.com/pub/gdb/releases/${P}.tar.bz2"
fi
SRC_URI="${SRC_URI} ${PATCH_VER:+mirror://gentoo/${P}-patches-${PATCH_VER}.tar.xz}"

LICENSE="GPL-2 LGPL-2"
is_cross \
	&& SLOT="${CTARGET}" \
	|| SLOT="0"
KEYWORDS=""
IUSE="expat multitarget nls python test vanilla"

RDEPEND=">=sys-libs/ncurses-5.2-r2
	sys-libs/readline
	expat? ( dev-libs/expat )
	python? ( =dev-lang/python-2* )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	test? ( dev-util/dejagnu )
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	[[ -n ${RPM} ]] && rpm_spec_epatch "${WORKDIR}"/gdb.spec
	use vanilla || [[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/patch
	strip-linguas -u bfd/po opcodes/po
}

gdb_branding() {
	printf "Gentoo ${PV} "
	if [[ -n ${PATCH_VER} ]] ; then
		printf "p${PATCH_VER}"
	else
		printf "vanilla"
	fi
}

src_configure() {
	strip-unsupported-flags
	econf \
		--with-pkgversion="$(gdb_branding)" \
		--with-bugurl='http://bugs.gentoo.org/' \
		--disable-werror \
		--enable-64-bit-bfd \
		$(has_version '=sys-libs/readline-5*:0' && echo --with-system-readline) \
		$(is_cross && echo --with-sysroot=/usr/${CTARGET}) \
		$(use_with expat) \
		$(use_enable nls) \
		$(use multitarget && echo --enable-targets=all) \
		$(use_with python python "${EPREFIX}/usr/bin/python2")
}

src_test() {
	emake check || ewarn "tests failed"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		libdir=/nukeme/pretty/pretty/please includedir=/nukeme/pretty/pretty/please \
		install || die
	rm -r "${D}"/nukeme || die

	# Don't install docs when building a cross-gdb
	if [[ ${CTARGET} != ${CHOST} ]] ; then
		rm -r "${D}"/usr/share
		return 0
	fi

	dodoc README
	docinto gdb
	dodoc gdb/CONTRIBUTE gdb/README gdb/MAINTAINERS \
		gdb/NEWS gdb/ChangeLog gdb/PROBLEMS
	docinto sim
	dodoc sim/ChangeLog sim/MAINTAINERS sim/README-HACKING

	dodoc "${WORKDIR}"/extra/gdbinit.sample

	# Remove shared info pages
	rm -f "${D}"/usr/share/info/{annotate,bfd,configure,standards}.info*
}

pkg_postinst() {
	# portage sucks and doesnt unmerge files in /etc
	rm -vf "${ROOT}"/etc/skel/.gdbinit
}