[gentoo-commits] gentoo-x86 commit in sys-auth/consolekit: ChangeLog consolekit-0.4.1-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/08/21 09:35:16

  Modified:             ChangeLog
  Added:                consolekit-0.4.1-r1.ebuild
  Log:
  Don't take bus name until ready wrt #333349. Don't daemonize when activated.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.74                 sys-auth/consolekit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	18 Aug 2010 21:50:37 -0000	1.73
+++ ChangeLog	21 Aug 2010 09:35:16 -0000	1.74
@@ -1,6 +1,14 @@
 # ChangeLog for sys-auth/consolekit
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v 1.73 2010/08/18 21:50:37 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v 1.74 2010/08/21 09:35:16 ssuominen Exp $
+
+*consolekit-0.4.1-r1 (21 Aug 2010)
+
+  21 Aug 2010; Samuli Suominen <ssuominen@g.o>
+  +consolekit-0.4.1-r1.ebuild, +files/consolekit-0.4.1-nodaemon.patch,
+  +files/consolekit-0.4.1-reorder-initialization.patch:
+  Don't take bus name until ready wrt #333349. Don't daemonize when
+  activated.
 
   18 Aug 2010; Markus Meier <maekke@g.o> consolekit-0.4.1.ebuild:
   arm stable, bug #314899



1.1                  sys-auth/consolekit/consolekit-0.4.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: consolekit-0.4.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/consolekit-0.4.1-r1.ebuild,v 1.1 2010/08/21 09:35:16 ssuominen Exp $

EAPI="3"

inherit autotools eutils multilib pam

MY_PN="ConsoleKit"
MY_PV="${PV//_pre*/}"
MY_P="${MY_PN}-${MY_PV}"

# FIXME: Report on upstream for patch about policies ? (probably upstream devs wanted this behaviour as default...)
DESCRIPTION="Framework for defining and tracking users, login sessions and seats."
HOMEPAGE="http://www.freedesktop.org/wiki/Software/ConsoleKit"
SRC_URI="http://www.freedesktop.org/software/${MY_PN}/dist/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux"
IUSE="debug doc pam policykit"

RDEPEND=">=dev-libs/glib-2.16
	>=dev-libs/dbus-glib-0.76
	>=x11-libs/libX11-1.0.0
	pam? ( virtual/pam )
	policykit? ( >=sys-auth/polkit-0.92 )
	elibc_glibc? ( !=sys-libs/glibc-2.4* )
	sys-libs/zlib"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-libs/libxslt
	doc? ( app-text/xmlto )"

S=${WORKDIR}/${MY_PN}-${MY_PV}

src_prepare() {
	# Clean up at_console compat files, bug #257761
	epatch "${FILESDIR}"/${PN}-0.2.10-cleanup_console_tags.patch

	# Fix automagic dependency on policykit
	epatch "${FILESDIR}"/${PN}-0.4.0-polkit-automagic.patch

	# Fix multilib support
	epatch "${FILESDIR}"/${PN}-0.4.0-multilib.patch

	# Be able to shutdown or reboot even without polkit or RBAC supports
	epatch "${FILESDIR}"/${P}-shutdown-reboot-without-policies.patch

	epatch "${FILESDIR}"/${P}-reorder-initialization.patch #333349
	epatch "${FILESDIR}"/${P}-nodaemon.patch

	eautoreconf
}

src_configure() {
	econf \
		XMLTO_FLAGS="--skip-validation" \
		$(use_enable debug) \
		$(use_enable doc docbook-docs) \
		$(use_enable pam pam-module) \
		$(use_enable policykit polkit) \
		--with-pam-module-dir=$(getpam_mod_dir) \
		--with-dbus-services="${EPREFIX}"/usr/share/dbus-1/services/ \
		--localstatedir="${EPREFIX}"/var
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# crappy Redhat init script
	rm -f "${ED}/etc/rc.d/init.d/ConsoleKit"

	# Portage barfs on .la files
	rm -f "${ED}/$(get_libdir)/security/pam_ck_connector.la"

	# Gentoo style init script
	newinitd "${FILESDIR}"/${PN}-0.1.rc consolekit

	# Some PM drop empty dirs, bug #257164
	keepdir /usr/$(get_libdir)/ConsoleKit/run-session.d
	keepdir /etc/ConsoleKit/run-session.d
	keepdir /var/run/ConsoleKit
	keepdir /var/log/ConsoleKit

	exeinto /etc/X11/xinit/xinitrc.d/
	doexe "${FILESDIR}/90-consolekit" || die "doexe failed"

	exeinto /usr/$(get_libdir)/ConsoleKit/run-session.d/
	doexe "${FILESDIR}/pam-foreground-compat.ck" || die "doexe failed"
}

pkg_postinst() {
	ewarn
	ewarn "You need to restart ConsoleKit to get the new features."
	ewarn "This can be done with /etc/init.d/consolekit restart"
	ewarn "but make sure you do this and then restart your session"
	ewarn "otherwise you will get access denied for certain actions"
}