[gentoo-commits] gentoo-x86 commit in games-roguelike/angband: metadata.xml ChangeLog angband-3.1.2_p2.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/02/16 22:25:14

  Modified:             metadata.xml ChangeLog
  Added:                angband-3.1.2_p2.ebuild
  Log:
  version bump (bug #299406) with development from Widget and ssuominen
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.3                  games-roguelike/angband/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/angband/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	4 Mar 2004 17:04:21 -0000	1.2
+++ metadata.xml	16 Feb 2010 22:25:13 -0000	1.3
@@ -1,5 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>games</herd>
+	<herd>games</herd>
+	<use>
+		<flag name='sound'>Enable and install sounds</flag>
+	</use>
 </pkgmetadata>



1.30                 games-roguelike/angband/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	7 Jan 2010 22:04:12 -0000	1.29
+++ ChangeLog	16 Feb 2010 22:25:13 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for games-roguelike/angband
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.29 2010/01/07 22:04:12 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.30 2010/02/16 22:25:13 mr_bones_ Exp $
+
+*angband-3.1.2_p2 (16 Feb 2010)
+
+  16 Feb 2010; Michael Sterrett <mr_bones_@g.o>
+  +angband-3.1.2_p2.ebuild:
+  version bump (bug #299406) with development from Widget and ssuominen
 
   07 Jan 2010; Joseph Jezak <josejx@g.o> angband-3.0.9e.ebuild:
   Marked ppc stable for bug #294528.



1.1                  games-roguelike/angband/angband-3.1.2_p2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/angband-3.1.2_p2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-roguelike/angband/angband-3.1.2_p2.ebuild?rev=1.1&content-type=text/plain

Index: angband-3.1.2_p2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/angband-3.1.2_p2.ebuild,v 1.1 2010/02/16 22:25:13 mr_bones_ Exp $

EAPI=2
inherit versionator games

MAJOR_PV=$(get_version_component_range 1-2)
MY_P=${P/_p/v}

DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
HOMEPAGE="http://rephial.org/"
SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${MY_P}-src.tar.gz"

LICENSE="Moria"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gtk ncurses sdl +sound X"

RDEPEND="gtk? ( gnome-base/libglade
	   x11-libs/pango
	   x11-libs/gtk+:2
	   dev-libs/glib:2 )
	X? ( x11-libs/libSM
		 x11-libs/libX11 )
	!ncurses? ( !X? ( !sdl? ( !gtk? ( sys-libs/ncurses ) ) ) )
	sdl? ( media-libs/libsdl[video,X]
		media-libs/sdl-ttf
		media-libs/sdl-image
		sound? ( media-libs/sdl-mixer
			media-libs/libsdl[audio] ) )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myconf

	if use sdl; then
		myconf="$(use_enable sound sdl-mixer)"
	else
		myconf="--disable-sdl-mixer"
	fi

	econf \
		--bindir="${GAMES_BINDIR}" \
		--with-configpath="${GAMES_SYSCONFDIR}/${PN}" \
		--with-libpath="${GAMES_DATADIR}/${PN}" \
		--with-varpath="${GAMES_STATEDIR}/${PN}" \
		--with-private-dirs \
		$(use_enable X x11) \
		$(use_enable gtk) \
		$(use_enable sdl) \
		$(use_enable ncurses curses) \
		$( use !gtk && use !sdl && use !ncurses && use !X && \
			echo --enable-curses) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Edit files are now system config files in Angband, but
	# users will be hidden from applying updates by default
	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
		> "${T}"/99${PN}
	doenvd "${T}"/99${PN} || die

	dodoc changes.txt faq.txt readme.txt thanks.txt || die

	# Create desktop entries if required.
	ICON_LOC="${GAMES_DATADIR}/${PN}/xtra/icon/att-32.png"
	if use X; then
		make_desktop_entry "angband -mx11" "Angband (X11)" "${ICON_LOC}" || die
	fi

	if use sdl; then
		make_desktop_entry "angband -msdl" "Angband (SDL)" "${ICON_LOC}" || die
	fi

	if use gtk; then
		make_desktop_entry "angband -mgtk" "Angband (GTK)" "${ICON_LOC}" || die
	fi

	use ncurses || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/graf"
	use sound || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/sound"

	prepgamesdirs
}

pkg_postinst() {
	echo
	elog "Angband now uses private savefiles instead of system-wide ones"
	elog "This version of Angband is not compatible with the save files"
	elog "of previous versions"
	echo

	games_pkg_postinst
}