[gentoo-commits] gentoo-x86 commit in dev-java/icedtea6-bin: ChangeLog icedtea6-bin-1.7.ebuild

[Vlastimil Babka (caster)]

caster      10/02/01 09:13:42

  Modified:             ChangeLog
  Added:                icedtea6-bin-1.7.ebuild
  Log:
  Version bump. Contains new IcedTeaNPPlugin compatible with xulrunner 1.9.1 and 1.9.2, Firefox 3.5+, Chromium. Also compatible with both jpeg-7 and jpeg-8 - the ebuild detects the installed version in src_unpack().
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.14                 dev-java/icedtea6-bin/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icedtea6-bin/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icedtea6-bin/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icedtea6-bin/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/icedtea6-bin/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	22 Jan 2010 10:25:17 -0000	1.13
+++ ChangeLog	1 Feb 2010 09:13:41 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/icedtea6-bin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea6-bin/ChangeLog,v 1.13 2010/01/22 10:25:17 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea6-bin/ChangeLog,v 1.14 2010/02/01 09:13:41 caster Exp $
+
+*icedtea6-bin-1.7 (01 Feb 2010)
+
+  01 Feb 2010; Vlastimil Babka <caster@g.o> +icedtea6-bin-1.7.ebuild:
+  Version bump. Contains new IcedTeaNPPlugin compatible with xulrunner 1.9.1
+  and 1.9.2, Firefox 3.5+, Chromium. Also compatible with both jpeg-7 and
+  jpeg-8 - the ebuild detects the installed version in src_unpack().
 
 *icedtea6-bin-1.6.2-r2 (22 Jan 2010)
 



1.1                  dev-java/icedtea6-bin/icedtea6-bin-1.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icedtea6-bin/icedtea6-bin-1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icedtea6-bin/icedtea6-bin-1.7.ebuild?rev=1.1&content-type=text/plain

Index: icedtea6-bin-1.7.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea6-bin/icedtea6-bin-1.7.ebuild,v 1.1 2010/02/01 09:13:41 caster Exp $

EAPI="1"

inherit java-vm-2

dist="mirror://gentoo/"
DESCRIPTION="A Gentoo-made binary build of the icedtea6 JDK"
TARBALL_VERSION="${PVR}"
SRC_URI="amd64? ( ${dist}/${PN}-core-${TARBALL_VERSION}-amd64.tar.bz2
		${dist}/${PN}-jpeg8-${TARBALL_VERSION}-amd64.tar.bz2 )
	x86? ( ${dist}/${PN}-core-${TARBALL_VERSION}-x86.tar.bz2
		${dist}/${PN}-jpeg8-${TARBALL_VERSION}-x86.tar.bz2 )
	doc? ( ${dist}/${PN}-doc-${TARBALL_VERSION}.tar.bz2 )
	examples? (
		amd64? ( ${dist}/${PN}-examples-${TARBALL_VERSION}-amd64.tar.bz2 )
		x86? ( ${dist}/${PN}-examples-${TARBALL_VERSION}-x86.tar.bz2 )
	)
	nsplugin? (
		amd64? ( ${dist}/${PN}-nsplugin-${TARBALL_VERSION}-amd64.tar.bz2 )
		x86? ( ${dist}/${PN}-nsplugin-${TARBALL_VERSION}-x86.tar.bz2 )
	)
	source? ( ${dist}/${PN}-src-${TARBALL_VERSION}.tar.bz2 )"
HOMEPAGE="http://icedtea.classpath.org"

IUSE="X alsa doc examples nsplugin source"
RESTRICT="strip"

LICENSE="GPL-2-with-linking-exception"
SLOT="0"
KEYWORDS="~amd64 ~x86"

S="${WORKDIR}/${PN}-${TARBALL_VERSION}"

RDEPEND=">=sys-devel/gcc-4.3
	>=sys-libs/glibc-2.9
	>=media-libs/giflib-4.1.6-r1
	>=media-libs/jpeg-7
	>=media-libs/libpng-1.2.38
	>=sys-libs/zlib-1.2.3-r1
	alsa? ( >=media-libs/alsa-lib-1.0.20 )
	X? (
		>=media-libs/freetype-2.3.9:2
		>=media-libs/fontconfig-2.6.0-r2:1.0
		>=x11-libs/libXext-1.0.5
		>=x11-libs/libXi-1.2.1
		>=x11-libs/libXtst-1.0.3
		>=x11-libs/libX11-1.2.2
		x11-libs/libXt
	)
	nsplugin? (
		>=dev-libs/atk-1.26.0
		>=dev-libs/glib-2.20.5:2
		>=dev-libs/nspr-4.8
		>=x11-libs/cairo-1.8.8
		>=x11-libs/gtk+-2.16.6:2
		>=x11-libs/pango-1.24.5
	)"
DEPEND=""

QA_EXECSTACK_amd64="opt/${P}/jre/lib/amd64/server/libjvm.so"
QA_EXECSTACK_x86="opt/${P}/jre/lib/i386/server/libjvm.so
	opt/${P}/jre/lib/i386/client/libjvm.so"

src_unpack() {
	unpack ${A}

	if has_version '>=media-libs/jpeg-8'; then
		einfo "Installing jpeg-8 ABI version"
		local arch=${ARCH}
		use x86 && arch=i386
		mv -v ${PN}-jpeg8/jre/lib/${arch}/*.so ${P}/jre/lib/${arch} || die
	else
		elog "Installing jpeg-7 ABI version"
		elog "You will have to remerge icedtea6-bin after upgrading to jpeg-8"
		elog "Note that revdep-rebuild will not do it automatically due to the mask file."
	fi
}

src_install() {
	local dest="/opt/${P}"
	local ddest="${D}/${dest}"
	dodir "${dest}" || die

	local arch=${ARCH}

	# doins can't handle symlinks.
	cp -pRP bin include jre lib man "${ddest}" || die "failed to copy"

	dodoc ../doc/{ASSEMBLY_EXCEPTION,THIRD_PARTY_README} || die
	if use doc ; then
		dohtml -r ../doc/html/* || die "Failed to install documentation"
	fi

	if use examples; then
		cp -pRP share/{demo,sample} "${ddest}" || die
	fi

	if use source ; then
		cp src.zip "${ddest}" || die
	fi

	if use nsplugin ; then
		use x86 && arch=i386
		install_mozilla_plugin "${dest}/jre/lib/${arch}/IcedTeaNPPlugin.so"
	fi

	set_java_env
	java-vm_revdep-mask
}

pkg_postinst() {
	# Set as default VM if none exists
	java-vm-2_pkg_postinst

	if use nsplugin; then
		elog "The icedtea6-bin browser plugin can be enabled using eselect java-nsplugin"
		elog "We now install the new IcedTeaNPPlugin, note that it's alpha quality."
		elog "Note that the plugin works only in browsers based on xulrunner-1.9.1+"
		elog "such as Firefox 3.5+ and recent Chromium versions."
	fi
}