[gentoo-commits] repo/gentoo:master commit in: dev-libs/gobject-introspection/

[Matt Turner]

commit:     15eff33f646f4d0b8ea878c51c1c492d530bb547
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 14 01:15:31 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Mar 14 01:15:31 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=15eff33f

dev-libs/gobject-introspection: Version bump to 1.76.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/gobject-introspection/Manifest            |  1 +
 .../gobject-introspection-1.76.0.ebuild            | 79 ++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index 883ececc6deb..4a7f9abc5e4b 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1,2 +1,3 @@
 DIST gobject-introspection-1.74.0.tar.xz 1044008 BLAKE2B 223bb9b8b452f03945f941086e47fb3b14f03f8353f4f903b21e3f494af728652a44de986752374057e90dd8111f21f5b0cd3e00bb0a8c3aa25c8261bb0b9247 SHA512 decff5dda0ec5ec0afda4d6bcd3bdadcbf34289002c0d9c0c77ecf8c5d3f15d196b24d8035041545031006acbdfe76af47c42da061c40e200c87f2c74cd301f0
 DIST gobject-introspection-1.75.6.tar.xz 1054100 BLAKE2B 3fb76550fc4f0ede1f0af93ef15d9923d25408ffc7d4f10fa4e10830ce1c7055760ec0fb11985f977eee9e81066e0712b4b6271398febd3e7592919db0335998 SHA512 6fb7b82c46eb79336ec654d34c94213bafd5ea6b293050698714c26afc929c73b6abbe75e09e992f0cccb7168f638a40219d6708e2758f620551a7b39306e0fb
+DIST gobject-introspection-1.76.0.tar.xz 1054488 BLAKE2B b5cc25977cf0a61b93fb98919f2c0e30e770431fdd4cfe85a564c50f9bd5e6ea9fec2b61c0b58f98c326c3007c361e1de0aee961538bcfd3b41fdb2a7e48a40b SHA512 76f3d2a74afbc3c819dee9350c39024b8665e704e01f63f877b431d59db42ee52ff636cb314c6be6e30b06bb21286ef37255467cc28ba434dc4dd72edc0cf8e9

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.76.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.76.0.ebuild
new file mode 100644
index 000000000000..7362abb83315
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.76.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="xml(+)"
+inherit gnome.org meson python-single-r1 xdg
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="doctool gtk-doc test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.75.0:2
+	dev-libs/libffi:=
+	doctool? (
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+# Wants real bison, not app-alternatives/yacc
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.19
+		app-text/docbook-xml-dtd:4.3
+		app-text/docbook-xml-dtd:4.5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	test? (
+		x11-libs/cairo[glib]
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test cairo)
+		$(meson_feature doctool)
+		#-Dglib_src_dir
+		$(meson_use gtk-doc gtk_doc)
+		#-Dcairo_libname
+		-Dpython="${EPYTHON}"
+		#-Dgir_dir_prefix
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	python_optimize "${ED}"/usr/$(get_libdir)/gobject-introspection/giscanner
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"/usr/share/aclocal/introspection.m4 \
+		"${ED}"/usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"/usr/share/aclocal || die
+}