[gentoo-commits] gentoo-x86 commit in www-apache/mod_httpbl: mod_httpbl-1.5-r1.ebuild ChangeLog mod_httpbl-1.5.ebuild

[Diego Petteno (flameeyes)]

flameeyes    09/11/30 16:51:14

  Modified:             ChangeLog
  Added:                mod_httpbl-1.5-r1.ebuild
  Removed:              mod_httpbl-1.5.ebuild
  Log:
  Revision bump, change the configuration file to disallow access to the diagnostics page by default.
  (Portage version: 2.2_rc54/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  www-apache/mod_httpbl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	26 Nov 2009 20:39:59 -0000	1.2
+++ ChangeLog	30 Nov 2009 16:51:14 -0000	1.3
@@ -1,6 +1,14 @@
 # ChangeLog for www-apache/mod_httpbl
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/ChangeLog,v 1.2 2009/11/26 20:39:59 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/ChangeLog,v 1.3 2009/11/30 16:51:14 flameeyes Exp $
+
+*mod_httpbl-1.5-r1 (30 Nov 2009)
+
+  30 Nov 2009; Diego E. Pettenò <flameeyes@g.o>
+  files/99_mod_httpbl.conf, -mod_httpbl-1.5.ebuild,
+  +mod_httpbl-1.5-r1.ebuild:
+  Revision bump, change the configuration file to disallow access to the
+  diagnostics page by default.
 
   26 Nov 2009; Diego E. Pettenò <flameeyes@g.o>
   files/99_mod_httpbl.conf, mod_httpbl-1.5.ebuild:



1.1                  www-apache/mod_httpbl/mod_httpbl-1.5-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: mod_httpbl-1.5-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_httpbl/mod_httpbl-1.5-r1.ebuild,v 1.1 2009/11/30 16:51:14 flameeyes Exp $

EAPI=2

inherit apache-module

DESCRIPTION="http:BL implementation for Apache 2"
HOMEPAGE="http://www.projecthoneypot.org/httpbl_download.php"
SRC_URI="http://httpbl.cvs.sourceforge.net/viewvc/*checkout*/httpbl/mod_httpbl_for_apache_2.0/mod_httpbl_source/mod_httpbl.c?revision=${PV} -> ${P}.c"

LICENSE="GPL-2"
SLOT="0"
IUSE="debug"

KEYWORDS="~amd64"

S=${WORKDIR}

APACHE2_MOD_FILE=".libs/${PN}.so"
APACHE2_MOD_CONF="99_mod_httpbl"
APACHE2_MOD_DEFINE="HTTPBL"

need_apache2

# We have to copy the file in the work directory because otherwise
# apxs will try to build it within distdir (which is luckily read
# only).
src_unpack() {
	cp "${DISTDIR}"/${P}.c ${PN}.c || die
}

src_prepare() {
	sed -i \
		-e '/#define VERBOSITY/i#ifndef VERBOSITY' \
		-e '/#define VERBOSITY/a#endif' \
		${PN}.c || die
}

src_compile() {
	APXS_FLAGS=
	for flag in ${CFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wc,${flag}"
	done

	if use debug; then
		APXS_FLAGS="${APXS_FLAGS} -DVERBOSITY=APLOG_DEBUG"
	fi

	# Yes we need to prefix it _twice_
	for flag in ${LDFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wl,${flag}"
	done

	${APXS} -c ${APXS_FLAGS} ${PN}.c || die
}

src_install() {
	apache-module_src_install

	keepdir /var/log/apache2/httpbl
	fowners apache:apache /var/log/apache2/httpbl || die
	fperms 0770 /var/log/apache2/httpbl || die

	keepdir /var/cache/mod_httpbl || die
	fowners apache:apache /var/cache/mod_httpbl || die
	fperms 0770 /var/cache/mod_httpbl || die
}

pkg_postinst() {
	apache-module_pkg_postinst

	elog "To use http:BL you will need the API key from Project Honey Pot"
	elog "that you can receive being an active member."
	elog "See ${HOMEPAGE} for details."
	elog ""
	elog "By default all requests are filtered with the blacklist, you probably"
	elog "want to restrict that to virtual hosts where actual applications are"
	elog "running and/or on possibly vulnerable locations."
}