[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.43.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    13/03/27 10:40:54

  Modified:             ChangeLog
  Added:                libdrm-2.4.43.ebuild
  Log:
  Version bump, drop exynos and freedreno support as they are broken in this release.
  
  (Portage version: 2.1.11.55/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.219                x11-libs/libdrm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.219&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.219&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?r1=1.218&r2=1.219

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v
retrieving revision 1.218
retrieving revision 1.219
diff -u -r1.218 -r1.219
--- ChangeLog	27 Feb 2013 05:40:26 -0000	1.218
+++ ChangeLog	27 Mar 2013 10:40:54 -0000	1.219
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.218 2013/02/27 05:40:26 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.219 2013/03/27 10:40:54 chithanh Exp $
+
+*libdrm-2.4.43 (27 Mar 2013)
+
+  27 Mar 2013; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +libdrm-2.4.43.ebuild:
+  Version bump, drop exynos and freedreno support as they are broken in this
+  release.
 
   27 Feb 2013; Zac Medico <zmedico@g.o> libdrm-2.4.42.ebuild:
   Add ~arm-linux keyword.



1.1                  x11-libs/libdrm/libdrm-2.4.43.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.43.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.43.ebuild?rev=1.1&content-type=text/plain

Index: libdrm-2.4.43.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.43.ebuild,v 1.1 2013/03/27 10:40:54 chithanh Exp $

EAPI=5
inherit xorg-2

EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"

DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
	SRC_URI=""
else
	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
VIDEO_CARDS="intel nouveau omap radeon vmware"
for card in ${VIDEO_CARDS}; do
	IUSE_VIDEO_CARDS+=" video_cards_${card}"
done

IUSE="${IUSE_VIDEO_CARDS} libkms"
RESTRICT="test" # see bug #236845

RDEPEND="dev-libs/libpthread-stubs
	video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
)

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		# tests are restricted, no point in building them
		sed -ie 's/tests //' "${S}"/Makefile.am
	fi
	xorg-2_src_prepare
}

src_configure() {
	XORG_CONFIGURE_OPTIONS=(
		--enable-udev
		$(use_enable video_cards_intel intel)
		$(use_enable video_cards_nouveau nouveau)
		$(use_enable video_cards_omap omap-experimental-api)
		$(use_enable video_cards_radeon radeon)
		$(use_enable video_cards_vmware vmwgfx)
		$(use_enable libkms)
	)
	xorg-2_src_configure
}