[gentoo-commits] gentoo-x86 commit in app-portage/layman: ChangeLog layman-1.4.2-r1.ebuild layman-1.4.2.ebuild

[Christian Ruppert (idl0r)]

idl0r       11/04/27 13:23:50

  Modified:             ChangeLog
  Added:                layman-1.4.2-r1.ebuild
  Removed:              layman-1.4.2.ebuild
  Log:
  Revision bump. The "python-compatbility-fix.patch" has been extended.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.136                app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?rev=1.136&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?rev=1.136&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?r1=1.135&r2=1.136

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.135
retrieving revision 1.136
diff -u -r1.135 -r1.136
--- ChangeLog	25 Apr 2011 19:43:01 -0000	1.135
+++ ChangeLog	27 Apr 2011 13:23:50 -0000	1.136
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.135 2011/04/25 19:43:01 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.136 2011/04/27 13:23:50 idl0r Exp $
+
+*layman-1.4.2-r1 (27 Apr 2011)
+
+  27 Apr 2011; Christian Ruppert <idl0r@g.o> -layman-1.4.2.ebuild,
+  +layman-1.4.2-r1.ebuild, files/layman-1.4.2-python-compatbility-fix.patch:
+  Revision bump. The "python-compatbility-fix.patch" has been extended.
 
   25 Apr 2011; Christian Ruppert <idl0r@g.o> layman-1.4.2.ebuild,
   +files/layman-1.4.2-python-compatbility-fix.patch:



1.1                  app-portage/layman/layman-1.4.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/layman-1.4.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/layman-1.4.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: layman-1.4.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-1.4.2-r1.ebuild,v 1.1 2011/04/27 13:23:50 idl0r Exp $

EAPI="2"
PYTHON_DEPEND="2:2.5"
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils

DESCRIPTION="Tool to manage Gentoo overlays."
HOMEPAGE="http://layman.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bazaar cvs darcs git mercurial subversion test"

COMMON_DEPS="dev-lang/python[xml]"
DEPEND="${COMMON_DEPS}
	test? ( dev-vcs/subversion )"
RDEPEND="${COMMON_DEPS}
	bazaar? ( dev-vcs/bzr )
	cvs? ( dev-vcs/cvs )
	darcs? ( dev-vcs/darcs )
	git? ( dev-vcs/git )
	mercurial? ( dev-vcs/mercurial )
	subversion? (
		|| (
			>=dev-vcs/subversion-1.5.4[webdav-neon]
			>=dev-vcs/subversion-1.5.4[webdav-serf]
		)
	)"
RESTRICT_PYTHON_ABIS="2.4 3.*"

src_prepare() {
	epatch "${FILESDIR}/${P}-python-compatbility-fix.patch"
}

# Prevent running make
src_compile() {
	:
}

src_test() {
	testing() {
		for suite in layman/tests/{dtest,external}.py ; do
			PYTHONPATH="." "$(PYTHON)" ${suite} \
					|| die "test suite '${suite}' failed"
		done
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	dodir /etc/layman

	cp etc/* "${D}"/etc/layman/

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /var/lib/layman
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo "You are now ready to add overlays into your system."
	einfo
	einfo "  layman -L"
	einfo
	einfo "will display a list of available overlays."
	einfo
	elog  "Select an overlay and add it using"
	elog
	elog  "  layman -a overlay-name"
	elog
	elog  "If this is the very first overlay you add with layman,"
	elog  "you need to append the following statement to your"
	elog  "/etc/make.conf file:"
	elog
	elog  "  source /var/lib/layman/make.conf"
	elog
	elog  "If you modify the 'storage' parameter in the layman"
	elog  "configuration file (/etc/layman/layman.cfg) you will"
	elog  "need to adapt the path given above to the new storage"
	elog  "directory."
	elog
	ewarn "Please add the 'source' statement to make.conf only AFTER "
	ewarn "you added your first overlay. Otherwise portage will fail."
	epause 5
}