[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-session: gnome-session-2.26.1-r1.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    09/06/26 20:49:45

  Modified:             ChangeLog
  Added:                gnome-session-2.26.1-r1.ebuild
  Log:
  Add build fix for bsd, check for execinfo and link to it if needed, bug #275524, gnome bug #587088
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.237                gnome-base/gnome-session/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.237&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.237&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?r1=1.236&r2=1.237

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v
retrieving revision 1.236
retrieving revision 1.237
diff -u -r1.236 -r1.237
--- ChangeLog	23 May 2009 14:54:11 -0000	1.236
+++ ChangeLog	26 Jun 2009 20:49:45 -0000	1.237
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/gnome-session
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.236 2009/05/23 14:54:11 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.237 2009/06/26 20:49:45 aballier Exp $
+
+*gnome-session-2.26.1-r1 (26 Jun 2009)
+
+  26 Jun 2009; Alexis Ballier <aballier@g.o>
+  +gnome-session-2.26.1-r1.ebuild,
+  +files/gnome-session-2.26.1-execinfo.patch:
+  Add build fix for bsd, check for execinfo and link to it if needed, bug
+  #275524, gnome bug #587088
 
   23 May 2009; Gilles Dartiguelongue <eva@g.o>
   -gnome-session-2.22.3.ebuild, gnome-session-2.26.1.ebuild:



1.1                  gnome-base/gnome-session/gnome-session-2.26.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/gnome-session-2.26.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/gnome-session-2.26.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-session-2.26.1-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/gnome-session-2.26.1-r1.ebuild,v 1.1 2009/06/26 20:49:45 aballier Exp $

EAPI="2"

inherit eutils gnome2 autotools

DESCRIPTION="Gnome session manager"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
	mirror://gentoo/${P}-gentoo-patches.tar.bz2
	branding? ( mirror://gentoo/gentoo-splash.png )"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE="branding doc ipv6 policykit elibc_FreeBSD"

RDEPEND=">=dev-libs/glib-2.16
	>=x11-libs/gtk+-2.11.1
	>=gnome-base/libglade-2.3.6
	>=dev-libs/dbus-glib-0.76
	>=gnome-base/gconf-2
	>=x11-libs/startup-notification-0.9
	policykit? ( >=gnome-extra/policykit-gnome-0.7 )
	elibc_FreeBSD? ( dev-libs/libexecinfo )

	x11-libs/libSM
	x11-libs/libICE
	x11-libs/libX11
	x11-libs/libXtst
	x11-apps/xdpyinfo"
DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	>=sys-devel/gettext-0.10.40
	>=dev-util/pkgconfig-0.17
	>=dev-util/intltool-0.40
	!<gnome-base/gdm-2.20.4
	doc? (
		app-text/xmlto
		dev-libs/libxslt )"
# gnome-base/gdm does not provide gnome.desktop anymore

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	# TODO: convert libnotify to a configure option
	G2CONF="${G2CONF}
		--docdir=/usr/share/doc/${PF}
		$(use_enable doc docbook-docs)
		$(use_enable ipv6)
		$(use_enable policykit polkit)"
}

src_prepare() {
	gnome2_src_prepare

	# Patch for Gentoo Branding (bug #42687)
	use branding && epatch "${FILESDIR}/${PN}-2.17.90.1-gentoo-branding.patch"

	# Fix shutdown/restart capability, upstream bug #549150
	epatch "${WORKDIR}/${PN}-2.26.1-shutdown.patch"

	# Add "session saving" button back, upstream bug #575544
	epatch "${WORKDIR}/${PN}-2.26.1-session-saving-button.patch"

	epatch "${FILESDIR}/${P}-execinfo.patch"
	eautoreconf
}

src_install() {
	gnome2_src_install

	dodir /etc/X11/Sessions
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}/Gnome" || die "doexe failed"

	# Our own splash for world domination
	if use branding ; then
		insinto /usr/share/pixmaps/splash/
		doins "${DISTDIR}/gentoo-splash.png" || die "doins failed"
	fi
}