[gentoo-commits] gentoo-x86 commit in app-office/texmaker: ChangeLog texmaker-4.2.ebuild

[Justin Lecher (jlec)]

jlec        14/05/22 13:08:13

  Modified:             ChangeLog
  Added:                texmaker-4.2.ebuild
  Log:
  app-office/texmaker: Version BUmp
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.140                app-office/texmaker/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.140&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.140&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?r1=1.139&r2=1.140

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v
retrieving revision 1.139
retrieving revision 1.140
diff -u -r1.139 -r1.140
--- ChangeLog	27 Jan 2014 14:59:49 -0000	1.139
+++ ChangeLog	22 May 2014 13:08:13 -0000	1.140
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/texmaker
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.139 2014/01/27 14:59:49 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.140 2014/05/22 13:08:13 jlec Exp $
+
+*texmaker-4.2 (22 May 2014)
+
+  22 May 2014; Justin Lecher <jlec@g.o> +texmaker-4.2.ebuild:
+  Version BUmp
 
   27 Jan 2014; Justin Lecher <jlec@g.o> texmaker-4.1.1.ebuild:
   Add missing USE dep



1.1                  app-office/texmaker/texmaker-4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.2.ebuild?rev=1.1&content-type=text/plain

Index: texmaker-4.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-4.2.ebuild,v 1.1 2014/05/22 13:08:13 jlec Exp $

EAPI=5

inherit qt4-r2 versionator

# The upstream version numbering is bad, so we have to remove a dot in the
# minor version number
MAJOR="$(get_major_version)"
MINOR_1="$(($(get_version_component_range 2)/10))"
MINOR_2="$(($(get_version_component_range 2)%10))"
if [ ${MINOR_2} -eq "0" ] ; then
	MY_P="${PN}-${MAJOR}.${MINOR_1}"
else
	MY_P="${PN}-${MAJOR}.${MINOR_1}.${MINOR_2}"
fi

MY_P="${P}"

DESCRIPTION="A nice LaTeX-IDE"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE=""

S="${WORKDIR}/${MY_P}"

COMMON_DEPEND="
	app-text/hunspell
	app-text/poppler:=[qt4]
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXext
	dev-qt/qtgui:4
	dev-qt/qtcore:4
	dev-qt/qtscript:4
	dev-qt/qtsingleapplication[X]
	dev-qt/qtwebkit:4
"
RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-i18n/ibus-qt
	app-text/psutils
	app-text/ghostscript-gpl
	media-libs/netpbm"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

PATCHES=( "${FILESDIR}"/${PN}-4.1-unbundle.patch )

DOCS=( utilities/AUTHORS utilities/CHANGELOG.txt )
HTML_DOCS=( doc/. )

src_prepare() {
	find singleapp hunspell -delete || die

	qt4-r2_src_prepare

	cat >> ${PN}.pro <<- EOF
	exists(texmakerx_my.pri):include(texmakerx_my.pri)
	EOF

	cp "${FILESDIR}"/texmakerx_my.pri . || die

	sed \
		-e '/^#include/s:hunspell/::g' \
		-e '/^#include/s:singleapp/::g' \
		-i *.cpp *.h || die
}

src_configure() {
	eqmake4 \
		${PN}.pro \
		PREFIX="${EPREFIX}/usr" \
		DESKTOPDIR="${EPREFIX}/usr/share/applications" \
		ICONDIR="${EPREFIX}/usr/share/pixmaps"
}

pkg_postinst() {
	elog "A user manual with many screenshots is available at:"
	elog "${EPREFIX}/usr/share/${PN}/usermanual_en.html"
}