[gentoo-commits] gentoo-x86 commit in app-admin/webapp-config: webapp-config-1.54.ebuild ChangeLog

[Devan Franchini (twitch153)]

twitch153    15/07/03 20:29:17

  Modified:             ChangeLog
  Added:                webapp-config-1.54.ebuild
  Log:
  Adds webapp-config version 1.54
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

Revision  Changes    Path
1.135                app-admin/webapp-config/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?rev=1.135&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?rev=1.135&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?r1=1.134&r2=1.135

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v
retrieving revision 1.134
retrieving revision 1.135
diff -u -r1.134 -r1.135
--- ChangeLog	22 Jun 2015 19:24:29 -0000	1.134
+++ ChangeLog	3 Jul 2015 20:29:17 -0000	1.135
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/webapp-config
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.134 2015/06/22 19:24:29 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.135 2015/07/03 20:29:17 twitch153 Exp $
+
+*webapp-config-1.54 (03 Jul 2015)
+
+  03 Jul 2015; Devan Franchini <twitch153@g.o>
+  +webapp-config-1.54.ebuild:
+  Adds webapp-config version 1.54
 
   22 Jun 2015; Devan Franchini <twitch153@g.o> webapp-config-9999.ebuild:
   Updates to git-r3 eclass



1.1                  app-admin/webapp-config/webapp-config-1.54.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/webapp-config-1.54.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/webapp-config-1.54.ebuild?rev=1.1&content-type=text/plain

Index: webapp-config-1.54.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-1.54.ebuild,v 1.1 2015/07/03 20:29:17 twitch153 Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )

inherit distutils-r1

SRC_URI="http://dev.gentoo.org/~twitch153/${PN}/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"

DESCRIPTION="Gentoo's installer for web-based applications"
HOMEPAGE="http://sourceforge.net/projects/webapp-config/"

LICENSE="GPL-2"
SLOT="0"
IUSE="+portage"

DEPEND="app-text/xmlto
	sys-apps/gentoo-functions"
RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"

python_compile_all() {
	emake -C doc/
}

python_install() {
	# According to this discussion:
	# http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
	# distutils does not provide for specifying two different script install
	# locations. Since we only install one script here the following should
	# be ok
	distutils-r1_python_install --install-scripts="/usr/sbin"
}

python_install_all() {
	distutils-r1_python_install_all

	insinto /etc/vhosts
	doins config/webapp-config

	keepdir /usr/share/webapps
	keepdir /var/db/webapps

	dodoc AUTHORS
	doman doc/*.[58]
	dohtml doc/*.[58].html
}

python_test() {
	PYTHONPATH="." "${PYTHON}" WebappConfig/tests/external.py \
		|| die "Testing failed with ${EPYTHON}"
}

pkg_postinst() {
	elog "webapp-config now requires that all -I/-U/-C commands be followed"
	elog "by the package name and package version of the webapp"
	elog "eg.) 'webapp-config -d drupal -I drupal 8.0.0_beta10'"
	elog "See 'man 8 webapp-config' for more information"
}