[gentoo-commits] gentoo-x86 commit in app-mobilephone/wammu: wammu-0.32.1.ebuild ChangeLog

[Christian Faulhammer (fauli)]

fauli       10/02/01 21:55:28

  Modified:             ChangeLog
  Added:                wammu-0.32.1.ebuild
  Log:
  version bump for bug 297729
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.42                 app-mobilephone/wammu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	24 Oct 2009 11:03:45 -0000	1.41
+++ ChangeLog	1 Feb 2010 21:55:28 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/wammu
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.41 2009/10/24 11:03:45 nixnut Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.42 2010/02/01 21:55:28 fauli Exp $
+
+*wammu-0.32.1 (01 Feb 2010)
+
+  01 Feb 2010; Christian Faulhammer <fauli@g.o> +wammu-0.32.1.ebuild:
+  version bump for bug 297729
 
   24 Oct 2009; nixnut <nixnut@g.o> wammu-0.30.1.ebuild:
   ppc stable #283672



1.1                  app-mobilephone/wammu/wammu-0.32.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/wammu-0.32.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/wammu/wammu-0.32.1.ebuild?rev=1.1&content-type=text/plain

Index: wammu-0.32.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/wammu-0.32.1.ebuild,v 1.1 2010/02/01 21:55:28 fauli Exp $

EAPI="2"

inherit distutils

DESCRIPTION="front-end for gammu (Nokia and other mobiles)"
HOMEPAGE="http://www.cihar.com/gammu/wammu/"
SRC_URI="http://dl.cihar.com/wammu/v0/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="bluetooth"

RDEPEND=">=app-mobilephone/gammu-1.25.0[python]
	>=dev-python/wxpython-2.8
	bluetooth? (
		|| (
			dev-python/pybluez
			net-wireless/gnome-bluetooth
		)
	)"
DEPEND="${RDEPEND}"

# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" af bg ca cs da de el es et fi fr gl he hu id it ko nl pl pt_BR ru sk sv zh_CN zh_TW"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

src_prepare() {
	local lang support_linguas=no
	for lang in ${MY_AVAILABLE_LINGUAS} ; do
		if use linguas_${lang} ; then
			support_linguas=yes
			break
		fi
	done
	# install all languages when all selected LINGUAS aren't supported
	if [ "${support_linguas}" = "yes" ]; then
		for lang in ${MY_AVAILABLE_LINGUAS} ; do
			if ! use linguas_${lang} ; then
				rm -r locale/${lang} || die
			fi
		done
	fi
}

src_compile() {
	# SKIPWXCHECK: else 'import wx' results in
	# Xlib: connection to ":0.0" refused by server
	SKIPWXCHECK=yes distutils_src_compile
}

src_install() {
	DOCS="AUTHORS FAQ"
	SKIPWXCHECK=yes distutils_src_install
}