[gentoo-commits] repo/gentoo:master commit in: dev-util/catalyst/

[Ben Kohler]

commit:     36040969e5f41263ebdd7133a8a760840b5c8408
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 31 19:19:52 2018 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Fri Aug 31 19:20:34 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36040969

dev-util/catalyst: add missing snakeoil RDEPEND, revbump

Fixes: https://bugs.gentoo.org/651230
Package-Manager: Portage-2.3.48, Repoman-2.3.10
RepoMan-Options: --force

 dev-util/catalyst/catalyst-3.0.2-r1.ebuild | 71 ++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/dev-util/catalyst/catalyst-3.0.2-r1.ebuild b/dev-util/catalyst/catalyst-3.0.2-r1.ebuild
new file mode 100644
index 00000000000..74acf27f4ce
--- /dev/null
+++ b/dev-util/catalyst/catalyst-3.0.2-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999* ]]; then
+	SRC_ECLASS="git-r3"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="mirror://gentoo/${P}.tar.bz2
+		https://dev.gentoo.org/~dolsen/releases/catalyst/${P}.tar.bz2
+		https://dev.gentoo.org/~jmbsvicetto/distfiles/${P}.tar.bz2
+		https://dev.gentoo.org/~zerochaos/distfiles/${P}.tar.bz2"
+	KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~x86-fbsd"
+fi
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit distutils-r1 ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ccache doc kernel_linux system-bootloader"
+
+DEPEND="
+	app-text/asciidoc
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	app-arch/lbzip2
+	app-crypt/shash
+	>=dev-python/pydecomp-0.2[${PYTHON_USEDEP}]
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	sys-fs/dosfstools
+	!kernel_FreeBSD? ( || ( app-arch/tar[xattr] app-arch/libarchive[xattr] ) )
+	kernel_FreeBSD? ( app-arch/libarchive[xattr] )
+	virtual/cdrtools
+	amd64? ( >=sys-boot/syslinux-3.72 )
+	x86? ( >=sys-boot/syslinux-3.72 )
+	ccache? ( dev-util/ccache )
+	kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
+"
+PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
+				sys-boot/grub:2
+				amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
+				x86? ( sys-boot/grub[grub_platforms_efi-32] )
+				sys-boot/syslinux
+				sys-boot/shim )"
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+	VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# build the man pages and docs
+	emake
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		dodoc files/HOWTO.html files/docbook-xsl.css
+	fi
+}