[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     65ece1f4f89e72a4bcac1097ff2c0eb712515ff1
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 28 16:54:41 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Sep 28 16:54:41 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65ece1f4

sys-kernel/gentoo-kernel-bin: add 5.10.69-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.69-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index ae3d67a14f9..cac5cf8ccb1 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -16,6 +16,7 @@ DIST gentoo-kernel-5.10.68-1.amd64.xpak 65497706 BLAKE2B 526ea1fc91fc906828366b4
 DIST gentoo-kernel-5.10.68-1.arm64.xpak 61234698 BLAKE2B f30cf0cd18711f3b42d9bfcb528ca56c7bafb88477414a3ed6ecd9c26b66fe76c1c1370461c3b1b83a13266240a20f55cbc35fd68d66bb8ca20503cc26f91f15 SHA512 df478abac49f43635cbe7b79faa188570cee3419d920877f05346fae7a3a16333f95c778d170b509277a0ee08c08d73589a177b69f86fdcdf800bde8481b903c
 DIST gentoo-kernel-5.10.68-1.x86.xpak 57237230 BLAKE2B be3156a79fc45bac92220f715e0e7270c060545f222d01fc24ff5bb6a239d8187077f6c4beba1d18c704c6e858f36b22db6f1ce9ebc737e574e9130410d5c813 SHA512 7ac97263d05bd70b29388d749786788124c6e636a3b1e975df8c9225ad3106d66a93898ce1e6cffefc4ec948a36830cfd3ae16dade66d3281bfebdd3a2bf6f7e
 DIST gentoo-kernel-5.10.69-1.amd64.xpak 65520787 BLAKE2B a96f97152bb31b016e2d4a04b97de4e4bdc404780fb4e6d066721bc7f7c7c47b6fc6ffde1afba6aff09b76a413c0e9a94b5d4a1cc6f4378d755a69d831c54c3f SHA512 040b51860d7bca583b2335b1ca2bb99d645705284a18a7ef838911ff2ba197bbd13009e881c700eefc1d5192a94f49261830c9cf2123fa0f2956971bf4738036
+DIST gentoo-kernel-5.10.69-1.arm64.xpak 61267801 BLAKE2B 466e762a98ec117fb32016ac9c6b16b1a78d784031b82194341c9787c0e42599cbace2452647f1c9146e0b90b56d2b8c6d458d9dbb6609cedc03059362b5b17e SHA512 c42443160b31bb5b705cba5e75742ff097ffd1f3e7956294ed6b2104ace2521008fac91c5a7882c13600b9759e0e996a88ffef6b8965b42ea313085213f6038a
 DIST gentoo-kernel-5.10.69-1.x86.xpak 57234909 BLAKE2B 2bc547a9370383560c151ee1a8a16e74e2202c1a7bf6877119a1ad1fa6776cb5fdd4c3ab6a711ef9d74e2790564593e9dfce9662ac788454a961026cbce7d1cf SHA512 7380a5a2db05fedf934383dd2fb85ca6e3909ebe8576abaae47e734cd4989d6c6fbdabd47062edb64c79b552831159801d1e1897972263f6adf42ad2c9d99171
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.69-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.69-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.69-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}