[gentoo-commits] gentoo-x86 commit in app-text/asciidoc: asciidoc-8.6.4.ebuild ChangeLog asciidoc-9999.ebuild

[Sebastian Pipping (sping)]

sping       11/02/22 07:40:40

  Modified:             ChangeLog asciidoc-9999.ebuild
  Added:                asciidoc-8.6.4.ebuild
  Log:
  app-text/asciidoc: Bump to 8.6.4
  
  (Portage version: 2.1.9.40/cvs/Linux x86_64)

Revision  Changes    Path
1.65                 app-text/asciidoc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	14 Nov 2010 19:28:43 -0000	1.64
+++ ChangeLog	22 Feb 2011 07:40:40 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/asciidoc
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v 1.64 2010/11/14 19:28:43 sping Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v 1.65 2011/02/22 07:40:40 sping Exp $
+
+*asciidoc-8.6.4 (22 Feb 2011)
+
+  22 Feb 2011; Sebastian Pipping <sping@g.o> +asciidoc-8.6.4.ebuild,
+  asciidoc-9999.ebuild:
+  Bump to 8.6.4, integrate test suite, sync live ebuild
 
 *asciidoc-9999 (14 Nov 2010)
 *asciidoc-8.6.3 (14 Nov 2010)



1.2                  app-text/asciidoc/asciidoc-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?r1=1.1&r2=1.2

Index: asciidoc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- asciidoc-9999.ebuild	14 Nov 2010 19:28:43 -0000	1.1
+++ asciidoc-9999.ebuild	22 Feb 2011 07:40:40 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.1 2010/11/14 19:28:43 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.2 2011/02/22 07:40:40 sping Exp $
 
 EAPI="3"
 
@@ -24,14 +24,20 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="examples vim-syntax"
+IUSE="examples test vim-syntax"
 
 RDEPEND=">=app-text/docbook-xsl-stylesheets-1.75
 		dev-libs/libxslt
 		media-gfx/graphviz
 		app-text/docbook-xml-dtd:4.5
 "
-DEPEND=""
+DEPEND="test? ( dev-util/source-highlight
+			media-sound/lilypond
+			media-gfx/imagemagick
+			dev-texlive/texlive-latex
+			app-text/dvipng
+			media-gfx/graphviz )
+"
 
 if [ "$PV" == "9999" ]; then
 	DEPEND="${DEPEND}
@@ -92,3 +98,9 @@
 	dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
 			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt || die
 }
+
+src_test() {
+	cd tests || die
+	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py update || die
+	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py run || die
+}



1.1                  app-text/asciidoc/asciidoc-8.6.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-8.6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-8.6.4.ebuild?rev=1.1&content-type=text/plain

Index: asciidoc-8.6.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-8.6.4.ebuild,v 1.1 2011/02/22 07:40:40 sping Exp $

EAPI="3"

PYTHON_DEPEND="2:2.5"
RESTRICT_PYTHON_ABIS="3.*"

[ "$PV" == "9999" ] && inherit mercurial autotools
inherit python

DESCRIPTION="A text document format for writing short documents, articles, books and UNIX man pages"
HOMEPAGE="http://www.methods.co.nz/asciidoc/"
if [ "$PV" == "9999" ]; then
	EHG_REPO_URI="https://asciidoc.googlecode.com/hg/"
	SRC_URI=""
	KEYWORDS=""
	S=${WORKDIR}/hg
else
	SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}/${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="examples test vim-syntax"

RDEPEND=">=app-text/docbook-xsl-stylesheets-1.75
		dev-libs/libxslt
		media-gfx/graphviz
		app-text/docbook-xml-dtd:4.5
"
DEPEND="test? ( dev-util/source-highlight
			media-sound/lilypond
			media-gfx/imagemagick
			dev-texlive/texlive-latex
			app-text/dvipng
			media-gfx/graphviz )
"

if [ "$PV" == "9999" ]; then
	DEPEND="${DEPEND}
		dev-util/aap
		www-client/lynx
		dev-util/source-highlight"
fi

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	if ! use vim-syntax; then
		sed -i -e '/^install/s/install-vim//' Makefile.in
	else
		sed -i\
			-e "/^vimdir/s:@sysconfdir@/vim:${EPREFIX}/usr/share/vim/vimfiles:" \
			-e 's:/etc/vim::' \
			Makefile.in || die
	fi

	# Only needed for prefix - harmless (does nothing) otherwise
	sed -i -e "s:^CONF_DIR=.*:CONF_DIR='${EPREFIX}/etc/asciidoc':" \
		"${S}/asciidoc.py" || die

	[ "$PV" == "9999" ] && eautoconf
}

src_configure() {
	econf --sysconfdir="${EPREFIX}"/usr/share
}

src_compile() {
	default

	if [ "$PV" == "9999" ]; then
		( cd doc && aap -f main.aap ../{CHANGELOG,README,BUGS} )
	fi
}

src_install() {
	use vim-syntax && dodir /usr/share/vim/vimfiles

	emake DESTDIR="${D}" install || die "install failed"

	python_convert_shebangs -r 2 "${D}"

	if use examples; then
		# This is a symlink to a directory
		rm examples/website/images || die

		insinto /usr/share/doc/${PF}
		doins -r examples || die
		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples || die
	fi

	dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt || die
}

src_test() {
	cd tests || die
	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py update || die
	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py run || die
}