[gentoo-commits] gentoo-x86 commit in net-firewall/shorewall-core: ChangeLog shorewall-core-4.5.21.2.ebuild

[Constanze Hausner (constanze)]

constanze    13/10/26 18:36:13

  Modified:             ChangeLog
  Added:                shorewall-core-4.5.21.2.ebuild
  Log:
  Version bump; Thanks to Thomas D.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key BB80F419010E3EC3)

Revision  Changes    Path
1.47                 net-firewall/shorewall-core/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall-core/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall-core/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall-core/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/shorewall-core/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	21 Oct 2013 12:54:52 -0000	1.46
+++ ChangeLog	26 Oct 2013 18:36:13 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for net-firewall/shorewall-core
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall-core/ChangeLog,v 1.46 2013/10/21 12:54:52 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall-core/ChangeLog,v 1.47 2013/10/26 18:36:13 constanze Exp $
+
+*shorewall-core-4.5.21.2 (26 Oct 2013)
+
+  26 Oct 2013; Constanze Hausner <constanze@g.o>
+  +files/4.5.21.2/shorewallrc, +shorewall-core-4.5.21.2.ebuild:
+  Version bump; Thanks to Thomas D.
 
   21 Oct 2013; Chema Alonso <nimiux@g.o>
   shorewall-core-4.5.18-r1.ebuild:



1.1                  net-firewall/shorewall-core/shorewall-core-4.5.21.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall-core/shorewall-core-4.5.21.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall-core/shorewall-core-4.5.21.2.ebuild?rev=1.1&content-type=text/plain

Index: shorewall-core-4.5.21.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall-core/shorewall-core-4.5.21.2.ebuild,v 1.1 2013/10/26 18:36:13 constanze Exp $

EAPI="5"

inherit eutils prefix versionator

MY_URL_PREFIX=
case ${P} in
	*_beta* | \
	*_rc*)
		MY_URL_PREFIX='development/'
		;;
esac

MY_PV=${PV/_rc/-RC}
MY_PV=${MY_PV/_beta/-Beta}
MY_P=${PN}-${MY_PV}

MY_MAJOR_RELEASE_NUMBER=$(get_version_component_range 1-2)
MY_MAJORMINOR_RELEASE_NUMBER=$(get_version_component_range 1-3)

DESCRIPTION="Core libraries of shorewall / shorewall(6)-lite"
HOMEPAGE="http://www.shorewall.net/"
SRC_URI="http://www1.shorewall.net/pub/shorewall/${MY_URL_PREFIX}${MY_MAJOR_RELEASE_NUMBER}/shorewall-${MY_MAJORMINOR_RELEASE_NUMBER}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="selinux"

DEPEND="
	>=dev-lang/perl-5.10
	virtual/perl-Digest-SHA
	!<net-firewall/shorewall-4.5.0.1
	selinux? ( sec-policy/selinux-shorewall )
"
RDEPEND="
	${DEPEND}
	>=net-firewall/iptables-1.4.20
	sys-apps/iproute2[-minimal]
	sys-devel/bc
	sys-apps/coreutils
"

DOCS=( changelog.txt releasenotes.txt )

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	cp "${FILESDIR}"/${PVR}/shorewallrc "${S}"/shorewallrc.gentoo || die "Copying shorewallrc failed"
	eprefixify "${S}"/shorewallrc.gentoo

	epatch_user
}

src_configure() {
	:;
}

src_install() {
	DESTDIR="${D}" ./install.sh shorewallrc.gentoo || die "install.sh failed"
	default
}

pkg_postinst() {
	if ! has_version sys-apps/net-tools; then
		elog "It is recommended to install sys-apps/net-tools which will provide the"
		elog "the 'arp' utility which will give you a better 'shorewall-lite dump' output:"
		elog ""
		elog "  # emerge sys-apps/net-tools"
	fi
}