[gentoo-commits] repo/gentoo:master commit in: sys-libs/libblockdev/

[Lars Wendler]

commit:     c37344309b25287456feb967982ad2cff0f9c355
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 26 11:33:27 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Apr 26 11:35:29 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3734430

sys-libs/libblockdev: Bump to version 2.17

Package-Manager: Portage-2.3.31, Repoman-2.3.9

 sys-libs/libblockdev/Manifest                |  1 +
 sys-libs/libblockdev/libblockdev-2.17.ebuild | 88 ++++++++++++++++++++++++++++
 sys-libs/libblockdev/metadata.xml            |  1 +
 3 files changed, 90 insertions(+)

diff --git a/sys-libs/libblockdev/Manifest b/sys-libs/libblockdev/Manifest
index dca4903571a..0cec0a74f46 100644
--- a/sys-libs/libblockdev/Manifest
+++ b/sys-libs/libblockdev/Manifest
@@ -1,3 +1,4 @@
 DIST libblockdev-2.14-1.tar.gz 274241 BLAKE2B 64c4c2a298ed95ed24a79716ccef5930f4276faaca02acf883c386b85a662d3fa1dc6f30e00d99bd835832e3c65acb89b445eff6fb35f9090dc949efde737d1a SHA512 fb80e840ed2f247912da93a6cc0cb1846be73dcc16b917f5231f5d7a87eaa7b43d07d5b2110038dd783fefa7ef7df0893785a60079ed02567f1e08bfcbd82343
 DIST libblockdev-2.15-1.tar.gz 279744 BLAKE2B caabeffdc2ee27bec63f0e799c632eab4e02867b866a83b03613e84567dbb0a5a6d8a59b4a34b9130b55a546bfa4a76b439bf901247da2d4d87b88b66c386ed6 SHA512 a58ee6ca75c0ee8706796afb6bf26334cc1716bb3ba9230f35c485643faf4921e70ff3a86ebb2be41b2d0177e68fdc0f8011e198e46d66aca9e9712a228c4ea3
 DIST libblockdev-2.16-1.tar.gz 282247 BLAKE2B 0645ffe9f0cadc6e412de813b32f4e37ead67039a69f7e8938b41f5ea10983a18d31e29653eab50dc41889952b00658b91853908dff3e62b50c1e85a267b4a63 SHA512 d48d4b0e3174ad7b93558534d7f0285b398e47e2c9dce3cc60cbe0a32a78fef32601cca2508f30a882609ceb3cc59efe2761720af191e6394ca1b8c51878b535
+DIST libblockdev-2.17-1.tar.gz 300882 BLAKE2B a7300ecf59a3ea37c2bb3245dcb4c0434ed8292e8fca87634224557112183de5fab2e66428d9b769537eebde341a3858182f9e9b9cefa68654c1d580fe4b63b2 SHA512 e882642e124100abf578699272bf1f0a2618b5eeed3ded4582f8535173238f145f3d4a2ea7dbe4b3b464d646f6e98ef0a891e7dfa7dde7e8c3322c883f7264e6

diff --git a/sys-libs/libblockdev/libblockdev-2.17.ebuild b/sys-libs/libblockdev/libblockdev-2.17.ebuild
new file mode 100644
index 00000000000..89b02d4392b
--- /dev/null
+++ b/sys-libs/libblockdev/libblockdev-2.17.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+inherit autotools python-single-r1
+
+MY_PV="${PV}-1"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A library for manipulating block devices"
+HOMEPAGE="https://github.com/rhinstaller/libblockdev"
+SRC_URI="https://github.com/rhinstaller/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="bcache +cryptsetup dmraid doc escrow lvm kbd test"
+
+CDEPEND="
+	>=dev-libs/glib-2.42.2
+	dev-libs/libbytesize
+	>=sys-apps/kmod-19
+	>=sys-apps/util-linux-2.27
+	>=sys-block/parted-3.1
+	cryptsetup? (
+		escrow? (
+			>=dev-libs/nss-3.18.0
+			dev-libs/volume_key
+		)
+		>=sys-fs/cryptsetup-1.6.7:=
+	)
+	dmraid? (
+		sys-fs/dmraid
+		sys-fs/lvm2
+	)
+	lvm? (
+		sys-fs/lvm2
+		virtual/udev
+	)
+	${PYTHON_DEPS}
+"
+
+DEPEND="
+	${CDEPEND}
+	>=dev-libs/gobject-introspection-1.3.0
+	doc? ( dev-util/gtk-doc )
+"
+
+RDEPEND="
+	${CDEPEND}
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+		escrow? ( cryptsetup )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-btrfs
+		--with-fs
+		--with-part
+		--without-mpath
+		--without-nvdimm
+		$(use_enable test tests)
+		$(use_with bcache)
+		$(use_with cryptsetup crypto)
+		$(use_with dmraid dm)
+		$(use_with doc gtk-doc)
+		$(use_with escrow)
+		$(use_with lvm lvm)
+		$(use_with lvm lvm-dbus)
+		$(use_with kbd)
+		$(use_with python_single_target_python2_7 python2)
+		$(use_with !python_single_target_python2_7 python3)
+	)
+	econf "${myeconfargs[@]}"
+}

diff --git a/sys-libs/libblockdev/metadata.xml b/sys-libs/libblockdev/metadata.xml
index 7fd674aa5a1..4f133ca27fa 100644
--- a/sys-libs/libblockdev/metadata.xml
+++ b/sys-libs/libblockdev/metadata.xml
@@ -8,6 +8,7 @@
   <use>
     <flag name="bcache">Enable block device cache support.</flag>
     <flag name="cryptsetup">Enable <pkg>sys-fs/cryptsetup</pkg> support</flag>
+    <flag name="escrow">Support for building crypto plugin with escrow device support</flag>
     <flag name="dmraid">Support for dmraid devices, also known as ATA-RAID, or Fake RAID.</flag>
     <flag name="lvm">Enable support for Logical Volume Management via <pkg>sys-fs/lvm2</pkg>.</flag>
     <flag name="kbd">Enable kernel block device support.</flag>