[gentoo-commits] gentoo-x86 commit in net-analyzer/openvas-manager: ChangeLog openvas-manager-5.0.4-r2.ebuild

[Justin Lecher (jlec)]

jlec        14/10/01 11:12:44

  Modified:             ChangeLog
  Added:                openvas-manager-5.0.4-r2.ebuild
  Log:
  net-analyzer/openvas-manager: Fix service dependency
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.13                 net-analyzer/openvas-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	1 Oct 2014 10:58:58 -0000	1.12
+++ ChangeLog	1 Oct 2014 11:12:44 -0000	1.13
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/openvas-manager
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v 1.12 2014/10/01 10:58:58 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v 1.13 2014/10/01 11:12:44 jlec Exp $
+
+*openvas-manager-5.0.4-r2 (01 Oct 2014)
+
+  01 Oct 2014; Justin Lecher <jlec@g.o>
+  +openvas-manager-5.0.4-r2.ebuild, files/openvasmd.init:
+  Fix service dependency
 
 *openvas-manager-5.0.4-r1 (01 Oct 2014)
 



1.1                  net-analyzer/openvas-manager/openvas-manager-5.0.4-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.4-r2.ebuild?rev=1.1&content-type=text/plain

Index: openvas-manager-5.0.4-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.4-r2.ebuild,v 1.1 2014/10/01 11:12:44 jlec Exp $

EAPI=5

inherit cmake-utils systemd

MY_PN=openvasmd

DESCRIPTION="A remote security scanner for Linux (openvas-manager)"
HOMEPAGE="http://www.openvas.org/"
SRC_URI="http://wald.intevation.org/frs/download.php/1730/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE=""

RDEPEND="
	>=net-analyzer/openvas-libraries-7.0.4
	>=dev-db/sqlite-3
	!net-analyzer/openvas-administrator"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-util/cmake"

PATCHES=(
	"${FILESDIR}"/${P}-gpgerror.patch
	"${FILESDIR}"/${P}-bsdsource.patch
	"${FILESDIR}"/${P}-run.patch
	)

src_prepare() {
	sed \
		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
		-i CMakeLists.txt || die
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DLOCALSTATEDIR="${EPREFIX}/var"
		-DSYSCONFDIR="${EPREFIX}/etc"
		)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	insinto /etc/openvas/
	doins "${FILESDIR}"/${MY_PN}-daemon.conf
	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${MY_PN}.logrotate ${MY_PN}

	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}
	systemd_dounit "${FILESDIR}"/${MY_PN}.service
}