[gentoo-commits] gentoo-x86 commit in gnome-extra/gucharmap: gucharmap-3.8.0.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/03/28 17:25:55

  Modified:             ChangeLog
  Added:                gucharmap-3.8.0.ebuild
  Log:
  Version bump for Gnome 3.8
  
  (Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.198                gnome-extra/gucharmap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?rev=1.198&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?rev=1.198&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?r1=1.197&r2=1.198

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v
retrieving revision 1.197
retrieving revision 1.198
diff -u -r1.197 -r1.198
--- ChangeLog	28 Mar 2013 15:57:40 -0000	1.197
+++ ChangeLog	28 Mar 2013 17:25:55 -0000	1.198
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-extra/gucharmap
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.197 2013/03/28 15:57:40 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.198 2013/03/28 17:25:55 pacho Exp $
+
+*gucharmap-3.8.0 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@g.o> +gucharmap-3.8.0.ebuild:
+  Version bump for Gnome 3.8
 
   28 Mar 2013; Agostino Sarubbo <ago@g.o> gucharmap-3.6.1.ebuild:
   Stable for arm, wrt bug #458984



1.1                  gnome-extra/gucharmap/gucharmap-3.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.8.0.ebuild?rev=1.1&content-type=text/plain

Index: gucharmap-3.8.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.8.0.ebuild,v 1.1 2013/03/28 17:25:55 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
VALA_MIN_API_VERSION="0.16"
VALA_USE_DEPEND="vapigen"

inherit autotools gnome2 vala

DESCRIPTION="Unicode character map viewer and library"
HOMEPAGE="http://live.gnome.org/Gucharmap"

LICENSE="GPL-3"
SLOT="2.90"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="cjk +introspection test vala"
REQUIRED_USE="vala? ( introspection )"

COMMON_DEPEND="
	>=dev-libs/glib-2.32:2
	>=x11-libs/pango-1.2.1[introspection?]
	>=x11-libs/gtk+-3.4.0:3[introspection?]

	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
"
RDEPEND="${COMMON_DEPEND}
	!<gnome-extra/gucharmap-3:0
"
DEPEND="${RDEPEND}
	app-text/yelp-tools
	>=dev-util/gtk-doc-am-1
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig
	test? (	app-text/docbook-xml-dtd:4.1.2 )
	vala? ( $(vala_depend) )
"

src_prepare() {
	G2CONF="${G2CONF}
		--disable-static
		$(use_enable introspection)
		$(use_enable cjk unihan)
		$(use_enable vala)"
	# Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
	# dependency here for some LINGUAS.

	# prevent file collisions with slot 0
	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
		-i configure.ac configure || die "sed configure.ac configure failed"

	eautoreconf
	use vala && vala_src_prepare
	gnome2_src_prepare

	# avoid autoreconf
	sed -e 's/-Wall //g' -i configure || die "sed failed"
}