[gentoo-commits] gentoo-x86 commit in games-fps/quakeforge: ChangeLog quakeforge-0.7.0.ebuild

[Alfredo Tupone (tupone)]

tupone      12/11/21 21:16:53

  Modified:             ChangeLog
  Added:                quakeforge-0.7.0.ebuild
  Log:
  Version bump to 0.7.0 Bug #405287
  
  (Portage version: 2.1.11.31/cvs/Linux i686, signed Manifest commit with key 0145142D)

Revision  Changes    Path
1.33                 games-fps/quakeforge/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/quakeforge/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/quakeforge/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/quakeforge/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/quakeforge/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	23 Jun 2012 14:17:57 -0000	1.32
+++ ChangeLog	21 Nov 2012 21:16:52 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/quakeforge
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/quakeforge/ChangeLog,v 1.32 2012/06/23 14:17:57 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/quakeforge/ChangeLog,v 1.33 2012/11/21 21:16:52 tupone Exp $
+
+*quakeforge-0.7.0 (21 Nov 2012)
+
+  21 Nov 2012; Tupone Alfredo <tupone@g.o> +quakeforge-0.7.0.ebuild,
+  +files/quakeforge-0.7.0-gentoo.patch:
+  Version bump to 0.7.0 Bug #405287 by Tim
 
   23 Jun 2012; Samuli Suominen <ssuominen@g.o> -quakeforge-0.5.5.ebuild:
   old



1.1                  games-fps/quakeforge/quakeforge-0.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/quakeforge/quakeforge-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/quakeforge/quakeforge-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: quakeforge-0.7.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/quakeforge/quakeforge-0.7.0.ebuild,v 1.1 2012/11/21 21:16:52 tupone Exp $

EAPI=4
inherit base eutils autotools games

DESCRIPTION="A new 3d engine based off of id Softwares's legendary Quake and QuakeWorld game engine"
HOMEPAGE="http://www.quakeforge.net/"
SRC_URI="mirror://sourceforge/quake/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="cdinstall debug fbcon flac opengl sdl svga X ncurses png vorbis zlib ipv6 xv dga alsa oss"
RESTRICT="userpriv"

RDEPEND="
	media-libs/libsamplerate
	net-misc/curl
	png? ( media-libs/libpng )
	flac? ( media-libs/flac )
	opengl? ( virtual/opengl )
	sdl? ( media-libs/libsdl )
	svga? ( media-libs/svgalib )
	X? (
		x11-libs/libX11
		x11-libs/libXext
	)
	ncurses? ( sys-libs/ncurses )
	vorbis? ( media-libs/libogg media-libs/libvorbis )
	zlib? ( sys-libs/zlib )
	xv? (
		x11-libs/libX11
		x11-libs/libXext
		x11-libs/libXxf86vm
	)
	dga? ( x11-libs/libXxf86dga )
	alsa? ( media-libs/alsa-lib )"
DEPEND="${RDEPEND}
	cdinstall? ( games-fps/quake1-data )
	sys-devel/bison
	sys-devel/flex"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	eautoreconf
}

src_configure() {
	local debugopts
	use debug \
		&& debugopts="--enable-debug --disable-optimize --enable-profile" \
		|| debugopts="--disable-debug --disable-profile"

	local clients=${QF_CLIENTS}
	use fbcon && clients="${clients},fbdev"
	use opengl && clients="${clients},glx"
	use sdl && clients="${clients},sdl,sdl32"
	use sdl && use opengl && clients="${clients},sgl"
	use svga && clients="${clients},svga"
	use X && clients="${clients},x11"
	use X && use opengl && clients="${clients},wgl"
	[ "${clients:0:1}" == "," ] && clients=${clients:1}

	local servers=${QF_SERVERS:-master,nq,qw,qtv}

	local tools=${QF_TOOLS:-all}

	local svgaconf	# use old school way for broken conf opts
	use svga \
		&& svgaconf="--with-svga=/usr" \
		|| svgaconf="--without-svga"

	addpredict "$(games_get_libdir)"
	egamesconf \
		$(use_enable ncurses curses) \
		$(use_enable vorbis) \
		$(use_enable png) \
		$(use_enable zlib) \
		$(use_with ipv6) \
		$(use_with fbcon fbdev) \
		${svgaconf} \
		$(use_with X x) \
		$(use_enable xv vidmode) \
		$(use_enable dga) \
		$(use_enable sdl) \
		--disable-xmms \
		$(use_enable alsa) \
		$(use_enable flac) \
		$(use_enable oss) \
		--enable-sound \
		--disable-optimize \
		${debugopts} \
		--with-global-cfg="${GAMES_SYSCONFDIR}"/quakeforge.conf \
		--with-sharepath="${GAMES_DATADIR}"/quake1 \
		--with-clients=${clients} \
		--with-servers=${servers} \
		--with-tools=${tools}
}

src_install() {
	emake -j1 DESTDIR="${D}" install
	mv "${D}/${GAMES_PREFIX}"/include "${D}"/usr/
	dodoc ChangeLog NEWS TODO
	prepgamesdirs
}

pkg_postinst() {
	# same warning used in quake1 / quakeforge / nprquake-sdl
	games_pkg_postinst
	echo
	elog "Before you can play, you must make sure"
	elog "${PN} can find your Quake .pak files"
	elog
	elog "You have 2 choices to do this"
	elog "1 Copy pak*.pak files to ${GAMES_DATADIR}/quake1/id1"
	elog "2 Symlink pak*.pak files in ${GAMES_DATADIR}/quake1/id1"
	elog
	elog "Example:"
	elog "my pak*.pak files are in /mnt/secondary/Games/Quake/Id1/"
	elog "ln -s /mnt/secondary/Games/Quake/Id1/pak0.pak ${GAMES_DATADIR}/quake1/id1/pak0.pak"
	elog
	elog "You only need pak0.pak to play the demo version,"
	elog "the others are needed for registered version"
}