[gentoo-commits] repo/gentoo:master commit in: net-misc/owncloud-client/

[Bernard Cafarelli]

commit:     ba1d457c6d1c46c7015bd7343a0b8eaaadbcbc4b
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 18 20:48:07 2022 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Tue Jan 18 22:34:34 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba1d457c

net-misc/owncloud-client: 2.10.0.6519 bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/owncloud-client/Manifest                  |  1 +
 .../owncloud-client-2.10.0.6519.ebuild             | 68 ++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 790331828236..5d29238c69e5 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
+DIST ownCloud-2.10.0.6519.tar.xz 5791912 BLAKE2B 3cf02ef89a6af249ab8f9d1b0a4cc899fbb11f49bf47ffb0ce042442da984d8dbf49619cf3344cf1837f1f3437e70f6e6d302f4e4c67a7df5f547368be4252ba SHA512 ab1e8aebefa049a73c436325b3b6e1d03e9a74f93ab6e090adbc71ccdd1cf56297898f004b12312ebba82158f5c2e299d9d0b13c14e291b855dcf267bac490f2
 DIST ownCloud-2.9.2.6206.tar.xz 5759996 BLAKE2B c328ea261a4fddecf93837dbcac01aab0971542d8dfb3f5b0a32a8432ca0e0904c3f4fc81c5c7811da8b3af64b58e929c055e7cec0649f00049e037372948eec SHA512 d075a11ee92aa9771c631a766feddfa1a70907d7d341b58043e1ba96ac52786a6a750b15c2f9b7a0992fe02a45586cc3445755dc9df4cd267e72f070d2222f0f

diff --git a/net-misc/owncloud-client/owncloud-client-2.10.0.6519.ebuild b/net-misc/owncloud-client/owncloud-client-2.10.0.6519.ebuild
new file mode 100644
index 000000000000..e75c66fabf69
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.10.0.6519.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dolphin gnome-keyring nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}