[gentoo-commits] gentoo-x86 commit in net-misc/radvd: radvd-1.9.1-r1.ebuild ChangeLog radvd-1.9.1.ebuild

[Michael Weber (xmw)]

xmw         12/07/02 06:47:29

  Modified:             ChangeLog
  Added:                radvd-1.9.1-r1.ebuild
  Removed:              radvd-1.9.1.ebuild
  Log:
  Add dev-libs/libdaemon as RDEPEND (bug 424361, thanks gurligebis)
  
  (Portage version: 2.1.11.3/cvs/Linux x86_64)

Revision  Changes    Path
1.92                 net-misc/radvd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	29 Jun 2012 08:09:52 -0000	1.91
+++ ChangeLog	2 Jul 2012 06:47:29 -0000	1.92
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/radvd
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.91 2012/06/29 08:09:52 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.92 2012/07/02 06:47:29 xmw Exp $
+
+*radvd-1.9.1-r1 (02 Jul 2012)
+
+  02 Jul 2012; Michael Weber <xmw@g.o> +radvd-1.9.1-r1.ebuild,
+  -radvd-1.9.1.ebuild:
+  Add dev-libs/libdaemon as RDEPEND (bug 424361, thanks gurligebis)
 
 *radvd-1.9.1 (29 Jun 2012)
 



1.1                  net-misc/radvd/radvd-1.9.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/radvd-1.9.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/radvd-1.9.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: radvd-1.9.1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-1.9.1-r1.ebuild,v 1.1 2012/07/02 06:47:29 xmw Exp $

EAPI=4

inherit user

DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
HOMEPAGE="http://v6web.litech.org/radvd/"
SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="kernel_FreeBSD selinux"

RDEPEND="dev-libs/libdaemon
	selinux? ( sec-policy/selinux-radvd )"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig"

DOCS=( CHANGES README TODO radvd.conf.example )

pkg_setup() {
	enewgroup radvd
	enewuser radvd -1 -1 /dev/null radvd

	# force ownership of radvd user and group (bug #19647)
	[[ -d ${ROOT}/var/run/radvd ]] && chown radvd:radvd "${ROOT}"/var/run/radvd
}

src_configure() {
	econf --with-pidfile=/var/run/radvd/radvd.pid
}

src_install() {
	default

	dohtml INTRO.html

	newinitd "${FILESDIR}"/${P}.init ${PN}
	newconfd "${FILESDIR}"/${PN}.conf ${PN}

	# location of radvd.pid needs to be writeable by the radvd user
	keepdir /var/run/radvd
	fowners -R radvd:radvd /var/run/radvd
	fperms 755 /var/run/radvd

	if use kernel_FreeBSD ; then
		sed -i -e \
			's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
			"${D}"/etc/init.d/${PN} || die
	fi
}

pkg_postinst() {
	elog
	elog "To use ${PN} you must create the configuration file"
	elog "${ROOT}etc/radvd.conf"
	elog
	elog "An example configuration file has been installed under"
	elog "${ROOT}usr/share/doc/${PF}"
	elog
	elog "grsecurity users should allow a specific group to read /proc"
	elog "and add the radvd user to that group, otherwise radvd may"
	elog "segfault on startup."
}