[gentoo-commits] gentoo-x86 commit in www-client/chromium: chromium-4.0.236.0.ebuild ChangeLog chromium-9999.ebuild chromium-4.0.221.5_p27967.ebuild chromium-4.0.222.6_p28888.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    09/11/05 13:20:14

  Modified:             ChangeLog chromium-9999.ebuild
  Added:                chromium-4.0.236.0.ebuild
  Removed:              chromium-4.0.221.5_p27967.ebuild
                        chromium-4.0.222.6_p28888.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc48/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	29 Oct 2009 08:41:42 -0000	1.16
+++ ChangeLog	5 Nov 2009 13:20:13 -0000	1.17
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.16 2009/10/29 08:41:42 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.17 2009/11/05 13:20:13 voyageur Exp $
+
+*chromium-4.0.236.0 (05 Nov 2009)
+
+  05 Nov 2009; Bernard Cafarelli <voyageur@g.o>
+  -chromium-4.0.221.5_p27967.ebuild, -chromium-4.0.222.6_p28888.ebuild,
+  +chromium-4.0.236.0.ebuild, chromium-9999.ebuild:
+  Version bump
 
   29 Oct 2009; Bernard Cafarelli <voyageur@g.o>
   chromium-4.0.221.5_p27967.ebuild, chromium-4.0.222.6_p28888.ebuild,



1.5                  www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.4&r2=1.5

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- chromium-9999.ebuild	29 Oct 2009 08:41:42 -0000	1.4
+++ chromium-9999.ebuild	5 Nov 2009 13:20:13 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.4 2009/10/29 08:41:42 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.5 2009/11/05 13:20:13 voyageur Exp $
 
 EAPI="2"
 inherit eutils multilib toolchain-funcs subversion
@@ -148,7 +148,6 @@
 
 	doins -r out/Release/locales
 	doins -r out/Release/resources
-	doins -r out/Release/themes
 
 	newman out/Release/chromium-browser.1 chrome.1
 



1.1                  www-client/chromium/chromium-4.0.236.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/chromium-4.0.236.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/chromium/chromium-4.0.236.0.ebuild?rev=1.1&content-type=text/plain

Index: chromium-4.0.236.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-4.0.236.0.ebuild,v 1.1 2009/11/05 13:20:13 voyageur Exp $

EAPI="2"
inherit eutils multilib toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
#SRC_URI="http://build.chromium.org/buildbot/archives/${P}.tar.bz2"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="app-arch/bzip2
	dev-libs/libxml2
	dev-libs/libxslt
	>=dev-libs/nss-3.12.2
	>=gnome-base/gconf-2.24.0
	media-fonts/corefonts
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg
	media-libs/libpng
	>=media-video/ffmpeg-0.5_p19787
	>=x11-libs/gtk+-2.14.7"
#	sys-libs/zlib
#	>=dev-libs/libevent-1.4.13
#	dev-db/sqlite:3
DEPEND="${RDEPEND}
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23"

export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser

src_prepare() {
	# Changing this in ~/include.gypi does not work
	sed -i "s/'-Werror'/''/" build/common.gypi || die "Werror sed failed"
	# Prevent automatic -march=pentium4 -msse2 enabling on x86, http://crbug.com/9007
	epatch "${FILESDIR}"/${PN}-drop_sse2.patch
	# Add configuration flag to use system libevent
	epatch "${FILESDIR}"/${PN}-use_system_libevent.patch

	# Display correct svn revision in about box (if not a release)
	if [[ "${PV}" =~ "_p" ]]; then
		echo "${PV/[0-9.]*\_p}" > build/LASTCHANGE.in || die "setting revision failed"
	fi
}

src_configure() {
	# CFLAGS/LDFLAGS
	mkdir -p "${S}"/.gyp
	cat << EOF > "${S}"/.gyp/include.gypi
{
	'target_defaults': {
		'cflags': [ '${CFLAGS// /','}' ],
		'ldflags': [ '${LDFLAGS// /','}' ],
	},
}
EOF
	export HOME="${S}"

	# Configuration options (system libraries)
	local myconf="-Duse_system_bzip2=1 -Duse_system_libjpeg=1 -Duse_system_libpng=1 -Duse_system_libxml=1 -Duse_system_libxslt=1 -Duse_system_ffmpeg=1"
	# -Duse_system_zlib=1: needs mozzconf.h and some MOZ_Z_* functions
	# -Duse_system_libevent=1: http://crbug.com/22140
	# -Duse_system_sqlite=1 : http://crbug.com/22208
	# Others still bundled: icu (not possible?), hunspell (changes required for sandbox support)

	# Sandbox paths
	myconf="${myconf} -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"

	if use amd64; then
		myconf="${myconf} -Dtarget_arch=x64"
	fi
	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}

src_compile() {
	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
		rootdir="${S}" \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		AR=$(tc-getAR) \
		RANLIB=$(tc-getRANLIB) \
		|| die "compilation failed"
}

src_install() {
	# Chromium does not have "install" target in the build system.

	dodir ${CHROMIUM_HOME}

	exeinto ${CHROMIUM_HOME}
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox
	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox
	doexe out/Release/xdg-settings
	doexe "${FILESDIR}"/chromium-launcher.sh

	insinto ${CHROMIUM_HOME}
	doins out/Release/chrome.pak

	doins -r out/Release/locales
	doins -r out/Release/resources

	newman out/Release/chromium-browser.1 chrome.1

	# Chromium looks for these in its folder
	# See media_posix.cc and base_paths_linux.cc
	dosym /usr/$(get_libdir)/libavcodec.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavformat.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavutil.so.50 ${CHROMIUM_HOME}

	# Plugins symlink
	dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/plugins

	newicon out/Release/product_logo_48.png ${PN}-browser.png
	dosym ${CHROMIUM_HOME}/chromium-launcher.sh /usr/bin/chromium
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
		|| die "desktop file sed failed"
}