[gentoo-commits] repo/gentoo:master commit in: x11-misc/mugshot/

[Conrad Kostecki]

commit:     9240c4b7e3420dc3d16e51b66d1dc545680ad237
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 15 12:44:26 2019 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Dec 15 13:08:18 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9240c4b7

x11-misc/mugshot: add python3_8 support

Also fixing QA error by calling python_optimize
and adding DISTUTILS_USE_SETUPTOOLS.

Updated dependencies, since not all deps are needed in DEPEND.

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 x11-misc/mugshot/mugshot-0.4.2-r1.ebuild | 79 ++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/x11-misc/mugshot/mugshot-0.4.2-r1.ebuild b/x11-misc/mugshot/mugshot-0.4.2-r1.ebuild
new file mode 100644
index 00000000000..d73d30cc473
--- /dev/null
+++ b/x11-misc/mugshot/mugshot-0.4.2-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS="no"
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+
+inherit distutils-r1 gnome2-utils xdg-utils
+
+DESCRIPTION="A lightweight user-configuration application"
+HOMEPAGE="https://github.com/bluesabre/mugshot"
+SRC_URI="https://github.com/bluesabre/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome libreoffice webcam"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	sys-apps/accountsservice
+	sys-apps/shadow
+	gnome? ( gnome-base/gnome-control-center )
+	libreoffice? (
+		|| (
+			app-office/libreoffice-bin
+			app-office/libreoffice
+		)
+	)
+	webcam? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-good:1.0
+		gnome? (
+			media-libs/clutter-gtk[introspection]
+			media-video/cheese[introspection]
+		)
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/gtk+:3[introspection]
+"
+
+BDEPEND="
+	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+	dev-util/intltool
+"
+
+S="${WORKDIR}/${PN}-${P}"
+
+python_install() {
+	distutils-r1_python_install
+
+	python_optimize
+
+	# Since DOCS are installed twice, remove the wrong path
+	rm -r "${ED}"/usr/share/doc/mugshot || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}