[gentoo-commits] repo/gentoo:master commit in: dev-java/antlr/

[Miroslav Šulc]

commit:     314148a1802a3bca0b6a9e32c39533a5d4255c3f
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Sun May 16 08:27:48 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sun May 16 19:06:09 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=314148a1

dev-java/antlr: EAPI 7, min java 1.8

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-java/antlr/antlr-2.7.7-r9.ebuild | 49 ++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-java/antlr/antlr-2.7.7-r9.ebuild b/dev-java/antlr/antlr-2.7.7-r9.ebuild
new file mode 100644
index 00000000000..f7a42851863
--- /dev/null
+++ b/dev-java/antlr/antlr-2.7.7-r9.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A parser generator for many languages"
+HOMEPAGE="https://www.antlr2.org/"
+SRC_URI="https://www.antlr2.org/download/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+
+RDEPEND=">=virtual/jre-1.8:*"
+DEPEND=">=virtual/jdk-1.8:*"
+
+S="${WORKDIR}/${P}"
+
+JAVA_SRC_DIR="${S}/${PN}"
+
+DOCS=( CHANGES.txt README.txt )
+
+src_prepare() {
+	default
+	java-pkg_clean
+
+	# Delete build files from examples.
+	find examples \( -name Makefile.in -o -name shiplist \) -delete || die
+}
+
+# Avoid configure script.
+src_configure() { :; }
+
+src_install() {
+	java-pkg-simple_src_install
+	java-pkg_dolauncher antlr --main antlr.Tool
+
+	use doc && java-pkg_dohtml -r doc/*
+	use examples && java-pkg_doexamples examples/java
+	use source && java-pkg_dosrc antlr
+
+	# https://bugs.gentoo.org/789582
+	einstalldocs
+}