[gentoo-commits] repo/gentoo:master commit in: media-sound/strawberry/

[Miroslav Šulc]

commit:     b1b2291d0b47fa96af709c2a24a85cc35a9c189a
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 27 04:34:02 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sat Aug 27 04:34:02 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b1b2291d

media-sound/strawberry: dropped obsolete 1.0.5

Bug: https://bugs.gentoo.org/866590
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/strawberry/Manifest                |   1 -
 media-sound/strawberry/strawberry-1.0.5.ebuild | 120 -------------------------
 2 files changed, 121 deletions(-)

diff --git a/media-sound/strawberry/Manifest b/media-sound/strawberry/Manifest
index 7fc58422d56e..e09411fb43b9 100644
--- a/media-sound/strawberry/Manifest
+++ b/media-sound/strawberry/Manifest
@@ -1,2 +1 @@
-DIST strawberry-1.0.5.tar.xz 11212028 BLAKE2B 2bb668bc9a4f66a9cdeaa28f47f21bf90f999d5524fa443bc7beaa1d0d7c6dc6727bf4df010fc06989e00fc34d62902add11186908fcf3f1b490c3bf745a9971 SHA512 4c625c75855f87952b274c85b4c5b021b27e75a74d46202ab3ea0aa3c86f510bccdece583483c4ba73e4733f151feb5eac5f5ef5d9a956995979fa307fd8d911
 DIST strawberry-1.0.7.tar.xz 11216436 BLAKE2B f7bc53f33be53fb9d947ea4f4c29827cc4248b0249904f2e48cbd9e4440de1f7f866d83c9fddc92cfb6f56b050c4dc40f0ad5e67a58c2a75e47a9d666847e9b3 SHA512 9bf092c3990ae0c2ce63074c7f6076ccab896ae915c4ee255a7fbb6534d50467648f3e96bc029075acfd50515c45ade867e55518d9a68ec9c10a741e1976d64f

diff --git a/media-sound/strawberry/strawberry-1.0.5.ebuild b/media-sound/strawberry/strawberry-1.0.5.ebuild
deleted file mode 100644
index 721ef2158d3d..000000000000
--- a/media-sound/strawberry/strawberry-1.0.5.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic plocale xdg
-
-PLOCALES="ca cs de es es_AR es_ES es_MX fi fr hu id it ja ko nb nl pl pt_BR ru sv uk zh_CN"
-
-DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
-HOMEPAGE="https://www.strawberrymusicplayer.org/"
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/strawberrymusicplayer/strawberry"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/strawberrymusicplayer/strawberry/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~ppc64 x86"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="cdda debug +gstreamer ipod moodbar mtp pulseaudio +udisks vlc"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-COMMON_DEPEND="
-	dev-db/sqlite:=
-	dev-libs/glib:2
-	dev-libs/protobuf:=
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtgui:5
-	dev-qt/qtnetwork:5[ssl]
-	dev-qt/qtsql:5[sqlite]
-	dev-qt/qtwidgets:5
-	dev-qt/qtx11extras:5
-	media-libs/alsa-lib
-	>=media-libs/taglib-1.11.1_p20181028
-	x11-libs/libX11
-	cdda? ( dev-libs/libcdio:= )
-	gstreamer? (
-		>=media-libs/chromaprint-1.4:=
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	ipod? ( >=media-libs/libgpod-0.8.0 )
-	moodbar? ( sci-libs/fftw:3.0 )
-	mtp? ( >=media-libs/libmtp-1.0.0 )
-	pulseaudio? ( media-sound/pulseaudio )
-	vlc? ( media-video/vlc )
-"
-# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
-RDEPEND="${COMMON_DEPEND}
-	gstreamer? (
-		media-plugins/gst-plugins-meta:1.0
-		media-plugins/gst-plugins-soup:1.0
-		media-plugins/gst-plugins-taglib:1.0
-	)
-	mtp? ( gnome-base/gvfs[mtp] )
-	udisks? ( sys-fs/udisks:2 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-cpp/gtest-1.8.0
-	dev-libs/boost
-	dev-qt/qttest:5
-"
-
-DOCS=( Changelog README.md )
-
-REQUIRED_USE="
-	cdda? ( gstreamer )
-	|| ( gstreamer vlc )
-"
-
-src_prepare() {
-	plocale_find_changes "src/translations" "" ".po"
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# spotify is not in portage
-	local mycmakeargs=(
-		-DBUILD_WERROR=OFF
-		# avoid automagically enabling of ccache (bug #611010)
-		-DCCACHE_EXECUTABLE=OFF
-		-DENABLE_GIO=ON
-		-DLINGUAS="$(plocale_get_locales)"
-		-DENABLE_AUDIOCD="$(usex cdda)"
-		-DENABLE_GSTREAMER="$(usex gstreamer)"
-		-DENABLE_LIBGPOD="$(usex ipod)"
-		-DENABLE_LIBMTP="$(usex mtp)"
-		-DENABLE_LIBPULSE="$(usex pulseaudio)"
-		-DENABLE_MOODBAR="$(usex moodbar)"
-		-DENABLE_MUSICBRAINZ="$(usex gstreamer)"
-		-DENABLE_SONGFINGERPRINTING="$(usex gstreamer)"
-		-DENABLE_UDISKS2="$(usex udisks)"
-		-DENABLE_VLC="$(usex vlc)"
-		# Disable until we have qt6 in the tree
-		-DWITH_QT6=OFF
-	)
-
-	use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
-
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if use gstreamer ; then
-		elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
-		elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
-		elog "depending on your preferences"
-	fi
-}