[gentoo-commits] gentoo-x86 commit in app-i18n/zinnia: zinnia-0.06-r3.ebuild ChangeLog

[Naohiro Aota (naota)]

naota       14/01/05 14:01:35

  Modified:             ChangeLog
  Added:                zinnia-0.06-r3.ebuild
  Log:
  Drop *.a files; Rewrite using autotools-utils.eclass #483248
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.9                  app-i18n/zinnia/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/zinnia/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/zinnia/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/zinnia/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/zinnia/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	10 Sep 2013 08:31:38 -0000	1.8
+++ ChangeLog	5 Jan 2014 14:01:35 -0000	1.9
@@ -1,6 +1,11 @@
 # ChangeLog for app-i18n/zinnia
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/zinnia/ChangeLog,v 1.8 2013/09/10 08:31:38 idella4 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/zinnia/ChangeLog,v 1.9 2014/01/05 14:01:35 naota Exp $
+
+*zinnia-0.06-r3 (05 Jan 2014)
+
+  05 Jan 2014; Naohiro Aota <naota@g.o> +zinnia-0.06-r3.ebuild:
+  Drop *.a files; Rewrite using autotools-utils.eclass #483248
 
 *zinnia-0.06-r2 (10 Sep 2013)
 



1.1                  app-i18n/zinnia/zinnia-0.06-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/zinnia/zinnia-0.06-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/zinnia/zinnia-0.06-r3.ebuild?rev=1.1&content-type=text/plain

Index: zinnia-0.06-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/zinnia/zinnia-0.06-r3.ebuild,v 1.1 2014/01/05 14:01:35 naota Exp $

EAPI=5
PERL_EXPORT_PHASE_FUNCTIONS=no
inherit perl-module eutils flag-o-matic toolchain-funcs autotools-utils

DESCRIPTION="Online hand recognition system with machine learning"
HOMEPAGE="http://zinnia.sourceforge.net/"
SRC_URI="mirror://sourceforge/zinnia/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# Package warrants IUSE doc
IUSE="perl static-libs"
DOCS=( AUTHORS ChangeLog NEWS README )
PATCHES=(
	"${FILESDIR}/${P}-ricedown.patch"
	"${FILESDIR}/${P}-perl.patch"
)
AUTOTOOLS_AUTORECONF=yes

src_prepare() {
	autotools-utils_src_prepare
	if use perl ; then
			pushd "${S}/perl" >/dev/null
			PATCHES=( ) perl-module_src_prepare
			popd >/dev/null
	fi
}

src_compile() {
	autotools-utils_src_compile
	if use perl ; then
			pushd "${S}"/perl >/dev/null

			# We need to run this here as otherwise it won't pick up the
			# just-built -lzinnia and cause the extension to have
			# undefined symbols.
			perl-module_src_configure

			append-cppflags "-I${S}"
			append-ldflags "-L${S}/.libs"

			emake \
				LDDLFLAGS="-shared" \
				OTHERLDFLAGS="${LDFLAGS}" \
				CC="$(tc-getCXX)" LD="$(tc-getCXX)" \
				OPTIMIZE="${CPPFLAGS} ${CXXFLAGS}"
			popd >/dev/null
	fi
}

src_install() {
	autotools-utils_src_install

	if use perl ; then
			pushd "${S}/perl" >/dev/null
			perl-module_src_install
			popd >/dev/null
	fi

	# Curiously ChangeLog & NEWS are left uncompressed
	dohtml doc/*.html doc/*.css
}